/*********************************************************************
     適当クローンスキルスクリプト by Mocha

新AthenaWiki【http://mocha.la.coocan.jp/pukiwiki/】
**********************************************************************
-----------------------------------------------------------------------------------------
[2007/05/3]
細部を修正

[2007/02/16]
クローン可能スキルを配列変数にして追加しやすいように変更。
今回も『No more "goto" Good bye "goto"運動』に挑戦。

by 暇人
---------------------------------------------------------------------------------------*/
-	script	qloneskillnpc	-1,{
//---------------------------------------------------------------------------------------

//鯖起動時初回のみ読込
	if('clone_npc_once ==0){

/**************************************
個人設定

*/

//スキルID
		setarray 'clone_skill_id[0],28,68,263,0,0,0,0,0,0,0;
		setarray 'clone_skill_id[10],0,0,0,0,0,0,0,0,0,0;
		setarray 'clone_skill_id[20],0,0,0,0,0,0,0,0,0,0;

//スキル名
		setarray 'clone_skill_name$[0],"ヒール","アスペルシオ","三段掌","","","","","","","";
		setarray 'clone_skill_name$[10],"","","","","","","","","","";
		setarray 'clone_skill_name$[20],"","","","","","","","","","";

//*************************************
/*スキルの種類数
		while('clone_skill_id[@clone_skill_kind] >0){
			set @clone_skill_kind,@clone_skill_kind +1;
		}
*/
//比較的新しいAthenaは↓で出来ます、↑はgetarraysizeが無い古いAthena用
		set '@clone_skill_kind,getarraysize('clone_skill_id);

//スキルの種類数から最大ページを算出
		set 'clone_max_page, '@clone_skill_kind /10 - (('@clone_skill_kind > 9) && (('@clone_skill_kind %10) == 0));	

//☆設定ここまで。
		set 'clone_npc_once,1;	//次から読込しないように。
	}
//---------------------------------------------------------------------------------------
	mes "[クローン屋]";
	mes "ここでは、超使えるスキルをひとつだけ覚えられるよ〜！";
	mes "費用は、な、なんと、無料だよ！";
	mes "クローンスキルを持っているローグ専用だけどね。";
	mes "やるかい？";
	next;
	if(select("やる","やめる")==2) {
		mes "[クローン屋]";
		mes "冷やかしは勘弁しておくれ。";
		close;
	}

	if (getskilllv(225) ==0){
		mes "[クローン屋]";
		mes "クローンスキルを持っていない";
		mes "君には関係ないな、またね。";
		close;
	}
//---------------------------------------------------------------------------------------
	set '@clone_now_page,0;	//初期ページ設定

//クローンスキル選択
	mes "[クローン屋]";
	mes "どのスキルを覚えるんだい？";
	next;

	do {
		set '@clone_choose,(select(
			(('@clone_now_page > 0)? "前へ":""),
			'clone_skill_name$['@clone_now_page *10 + 0],
			'clone_skill_name$['@clone_now_page *10 + 1],
			'clone_skill_name$['@clone_now_page *10 + 2],
			'clone_skill_name$['@clone_now_page *10 + 3],
			'clone_skill_name$['@clone_now_page *10 + 4],
			'clone_skill_name$['@clone_now_page *10 + 5],
			'clone_skill_name$['@clone_now_page *10 + 6],
			'clone_skill_name$['@clone_now_page *10 + 7],
			'clone_skill_name$['@clone_now_page *10 + 8],
			'clone_skill_name$['@clone_now_page *10 + 9],
			('@clone_now_page < 'clone_max_page)? "次へ" : ""));

//『前へ』を選択の場合
		if ('@clone_choose ==1){
			set '@clone_now_page,'@clone_now_page -1;
		}
//『次へ』
		else if ('@clone_choose==12){
			set '@clone_now_page,'@clone_now_page +1;
		}

	} while('@clone_choose ==1 || '@clone_choose ==12);

//選択された番号を記憶
	set '@clone_select,'@clone_now_page *10 + '@clone_choose -2;

//---------------------------------------------------------------------------------------
//クローンスキル取得
	gmcommand ("@cloneskill " + 'clone_skill_id['@clone_select]);

	mes 'clone_skill_name$['@clone_select] + "を覚えました。";
	next;

	mes "[クローン屋]";
	mes "またね。";
	close;

//---------------------------------------------------------------------------------------
}
//---------------------------------------------------------------------------------------
//【配置】
geffen.gat,128,104,4	duplicate(qloneskillnpc)	クローン屋#qlone_01	909