//ホムセンター
//セーブファイル(空ファイル)を作成して、パスを設定してください。
payo1.gat,100,117,3	ホムセンター	91,{
	if ('Read_First == 0) {	//初期設定用
		set 'Hom_Zeny,100000;
		set 'Hom_Save$,"script/original/db/Homunculus";
		close;
	}
	set @name$,"ホム管理人";
	mes @name$;
	if(getskilllv(243)){ //コールホムンクルスのチェック
		if(gethomuninfo(0) == 0){	//ホムを連れていない。
			mes "ホムを連れてきてくださいね。";
		}
		else {
			set '@Hom_Rows,csvfind('Hom_Save$, 0, getcharid(0));	//預かりホムの検索
			if('@Hom_Rows == -1){ //預かりホムなし
				mes "預かりホム：無し";
				set '@menu_mes$,"預ける";
			}
			else {	//預かりホムあり
				mes "預かりホム：" + csvread('Hom_Save$, '@Hom_Rows, 2);
				set '@menu_mes$,"交換する";
			}
			mes "いかがいたしましょう？";
			next;
			switch(select('@menu_mes$ + " - " + 'Hom_Zeny + "z","説明をお願いします。","やめる")){
				case 1:
					mes @name$;
					mes '@menu_mes$ + "のですね、よろしいですか？";
					next;
					if (select("はい","いいえ") == 1){
						mes @name$;
						if(Zeny <= 'Hom_Zeny){
							mes "お金が足りませんよ？";
						}
						else{
							for (set '@temp,0; 'Lock_CSV; set '@temp,'@temp + 1){
								if (!sleep2 ( 50 ) || '@temp == 10) {
									mes "エラーが発生しました。";
									close;
								}
							}
							set 'Lock_CSV,1;
							//所持ホムデータ取得	0:homun_id 1:homun_base_lv 2:homun_name 3:friendly 4:hungry 5:class　0と4は無理
							setarray '@In_Format$,getcharid(0),gethomuninfo(1),gethomuninfo(2),gethomuninfo(3),gethomuninfo(5);
							mes "(ホム削除中…)";
							homundel;
							if (!sleep2 ( 50 )) {
								set 'Lock_CSV,0;
								mes "エラーが発生しました。";
								close;
							}
							if (gethomuninfo(0) != 0){
								set 'Lock_CSV,0;
								mes "ホムの削除に失敗しました。";
								mes "安息状態でないか確認してください。";
								close;
							}
							set Zeny,Zeny - 'Hom_Zeny;
							//預かりホム召喚
							set '@Hom_Rows,csvfind('Hom_Save$, 0, getcharid(0));	//預かりホムの検索
							if('@Hom_Rows != -1){ //預かりホム召喚
								mes "(ホム召喚中…)";
								for (set '@temp,0; gethomuninfo(0) == 0; set '@temp,'@temp + 1){
									gmcommand "@makehomun " + csvread('Hom_Save$, '@Hom_Rows, 4);
									if (!sleep2 ( 50 ) || '@temp == 10) {
										set 'Lock_CSV,0;
										mes "エラーが発生しました。";
										close;
									}
								}
								mes "(ホムLv変更中…)";
								set '@Hom_Lv,csvread('Hom_Save$, '@Hom_Rows, 1);
								set '@Hom_Lv,'@Hom_Lv - 1;
								for (set '@temp,0; gethomuninfo(1) != '@Hom_Lv + 1; set '@temp,'@temp + 1){
									gmcommand "@homlv " + '@Hom_Lv;
									if (!sleep2 ( 50 ) || '@temp == 10) {
										set 'Lock_CSV,0;
										mes "エラーが発生しました。";
										close;
									}
								}
								mes "(ホム名前変更中…)";
								set '@Hom_Name$,csvread('Hom_Save$, '@Hom_Rows, 2);
								for (set '@temp,0; gethomuninfo(2) != '@Hom_Name$; set '@temp,'@temp + 1){
									homunrename '@Hom_Name$;
									if (!sleep2 ( 50 ) || '@temp == 10) {
										set 'Lock_CSV,0;
										mes "エラーが発生しました。";
										close;
									}
								}
								mes "(ホム友好度変更中…)";
								set '@Hom_friend,csvread('Hom_Save$, '@Hom_Rows, 3);
								for (set '@temp,0; gethomuninfo(3) != '@Hom_friend; set '@temp,'@temp + 1){
									gmcommand "@homfriendly " + '@Hom_friend;
									if (!sleep2 ( 50 ) || '@temp == 10) {
										set 'Lock_CSV,0;
										mes "エラーが発生しました。";
										close;
									}
								}
								csvdelete 'Hom_Save$,'@Hom_Rows;
							}
							mes "(ホム登録中…)";
							//所持ホムデータ書込
							csvinsert 'Hom_Save$, 0;
							csvwritearray 'Hom_Save$,0,'@In_Format$;
							csvflush 'Hom_Save$;
							set 'Lock_CSV,0;
							next;
							mes @name$;
							mes "ありがとうございました。";
							mes "またきてくださいね。";
						}
					}
					else{
						mes @name$;
						mes "キャンセルしました。";
						mes "またきてくださいね。";
					}
					break;
				case 2:
					mes @name$;
					mes "それでは、説明させていただきます。";
					mes "ホムンクルスを預ける事ができます。";
					mes "以上です。";
					next;
					mes "え？注意事項とかですか？";
					mes "あ、忘れてました。";
					mes "・預けるホムは１キャラ１体のみです。";
					mes "・ステータスは変化してしまいます。";
					mes "以上２点が注意事項です。";
					break;
				case 3:
					mes @name$;
					mes "またきてくださいね。";
					break;
			}
		}
	}
	else{
		mes "コールホムンクルスを覚えてきてくださいね。";
	}
	close;
}