// クリップエンチャント http://ro-server.net84.net/
payo1.gat,107,83,3	script	妖しい魔導士	735,{
	if (CardSetQue == 0){
		mes "[妖しい魔導士]";
		mes "カード…貼り付け…。";
		next;
		if(select("どうしたんですか？","・・・。") == 1) {
			mes "[妖しい魔導士]";
			mes "ん？ああ。";
			mes "カードって貼付部位が決まってるだろ？";
			mes "それが納得いかず研究してるんだが、";
			mes "MP使って別の部位に付けたいんだ。";
			mes "そうだ、実験に付き合ってくれないか？";
			next;
			switch(select("やりましょう","いやです")) {
				case 1:
					mes "[妖しい魔導士]";
					mes "おお、そうか！";
					mes "じゃあ、必要な事説明するぞ。";
					next;
					set CardSetQue,2;
					goto L_Introduction;
				case 2:
					mes "[妖しい魔導士]";
					mes "そうか…";
					mes "もし、手伝ってくれる気になったらまた話しかけてくれ。";
					set CardSetQue,1;
			}
		}
	}
	else if (CardSetQue == 1){
		mes "[妖しい魔導士]";
		mes "ん？手伝う気になってくれたのか？";
		next;
		switch(select("やりましょう","いやです")) {
			case 1:
				mes "[妖しい魔導士]";
				mes "おお、そうか！";
				mes "じゃあ、必要な事説明するぞ。";
				next;
				set CardSetQue,2;
				goto L_Introduction;
			case 2:
				mes "[妖しい魔導士]";
				mes "そうか…";
		}
	}
	else if (CardSetQue == 2){
		mes "[妖しい魔導士]";
		mes "準備はできたかい？";
		next;
			switch(select("出来ました！","もう一回説明を…")) {
				case 1:
					mes "[妖しい魔導士]";
					mes "おお、そうか！";
					mes "じゃあ、実験を開始するぞ。";
					next;
					goto L_Card_Composition;
				case 2:
					mes "[妖しい魔導士]";
					mes "忘れたのか？";
					mes "じゃあもう一回説明するぜ。";
					next;
					goto L_Introduction;
		}
	}
	else if (CardSetQue == 3){
		mes "[妖しい魔導士]";
		mes "お？また作りたいのか？";
		next;
		switch(select("はい","もう一回説明を…","いやです")) {
			case 1:
				mes "[妖しい魔導士]";
				mes "おお、そうか！";
				mes "じゃあ、実験を開始するぞ。";
				next;
				goto L_Card_Composition;
			case 2:
				mes "[妖しい魔導士]";
				mes "忘れたのか？";
				mes "じゃあもう一回説明するぜ。";
				next;
				goto L_Introduction;
			case 3:
				mes "[妖しい魔導士]";
				mes "そうか…";
		}
	}
	close;
L_Card_Composition:
		mes "[妖しい魔導士]";
		mes "よし、実験を始めるぜ！";
		next;
		//所持カードのロード
		getinventorylist;	//所持品リストのロード
		set '@num,0;
		for (set '@temp,0; '@temp <= @inventorylist_count; set '@temp, '@temp + 1){
			if (@inventorylist_id['@temp] == 2607 && @inventorylist_card1['@temp] > 0){
				mes "[妖しい魔導士]";
				mes "もうすでにカードが刺さってるクリップは倉庫に入れておいてくれ…";
				close;
			}
			if (@inventorylist_id['@temp] < 4001 || @inventorylist_id['@temp] > 5000) Continue;
			if (getitemname(@inventorylist_id['@temp]) == "") Continue;
			set '@card_list['@num],@inventorylist_id['@temp];
			set '@card_list$['@num],getitemname(@inventorylist_id['@temp]);
			set '@num,'@num + 1;
		}
		set '@list_num,0;
			mes "[妖しい魔導士]";
			mes "付けたいカードを選択してくれ。";
			set '@list_num,select(printarray('@card_list$)) - 1;
			set '@Card_NAME$,getitemname('@card_list['@list_num]);
			mes " ";
			mes '@Card_NAME$ + "　であってるかな？";
			next;
			if(select("はい","いいえ") == 2) {
				mes "そうか…";
				close;
			}
		while ('@Use_MP == 0){
			mes "[妖しい魔導士]";
			mes "使用するMPの量を指定してくれ。";
			mes "現在MP:" + PC_SHOP_POINT + "　(1〜∞)";
			mes "^ff0000ヒント：1000以上は700と同率です";
			input '@Use_MP;
			if('@Use_MP == 0){
				mes "ん、やめるのか？";
				if(select("はい","いいえ") == 1) {
					mes "そうか…";
					close;
				}
				next;
				continue;
			}
			else if('@Use_MP < 0 || '@Use_MP > PC_SHOP_POINT){
				mes "値がおかしいぜ？";
				set '@Use_MP,0;
				next;
				continue;
			}
			mes " ";
			mes '@Use_MP + "ポイントでいいかな？";
			next;
			if(select("はい","いいえ") == 2) {
				set '@Use_MP,0;
				continue;
			}
		}
		mes "[妖しい魔導士]";
		mes "カード名:" + '@Card_NAME$;
		mes "　使用MP:" + '@Use_MP;
		mes "これで実行するぜ？";
		if(select("ＯＫ！","やめる") == 2) {
			close;
		}
		mes " ";
		mes "−妖しい魔導士は";
		mes "　　　妖しい魔法を唱えた−";
		next;
		if (countitem(2607) == 0){
			mes "あれ？クリップがないぜ？";
			close;
		}
		if (countitem('@card_list['@list_num]) == 0){
			mes "あれ？カードがないぜ？";
			close;
		}
		delitem 2607,1;
		delitem '@card_list['@list_num],1;
		set PC_SHOP_POINT, PC_SHOP_POINT - '@Use_MP;
		if ('@Use_MP > 1000) set '@Border, 700;
		else {
			set '@seed1, '@Use_MP / 5;
			set '@seed2, (50 - ('@Use_MP % 100)) / 6;
			set '@seed2, '@seed2 * '@seed2;
			set '@Border, '@Use_MP - '@seed1 - '@seed2;
		}
		set '@randam, rand(1000);
		mes "−クリップとカードは重なり、";
		mes " ";
		if ('@Border < 101) mes "　　−何も起きることなく、";
		else if ('@Border < 301) mes "　　−赤い光を放ち、";
		else if ('@Border < 501) mes "　　−オレンジの光を放ち、";
		else if ('@Border < 701) mes "　　−黄色いの光を放ち、";
		else mes "　　−白い光を放ち、";
		mes " ";
		if ('@randam > '@Border){
			misceffect 155,getcharid(0);
			mes "　　　　−消滅した。";
			next;
			mes "[妖しい魔導士]";
			mes "すまない、どうやら失敗したようだ…。";
		}
		else{
			misceffect 154,getcharid(0);
			mes "　　　　−くっついた。";
			getitem2 2606,1,1,0,0,'@card_list['@list_num],0,0,0;
			next;
			mes "[妖しい魔導士]";
			mes "おめでとう、成功したぞ！";
		}
		mes " ";
		mes "ボーダー：^0000ff" + '@Border + "^000000未満なら成功";
		mes "成否判定：^ff0000" + '@randam + "^000000";
		next;
		mes "[妖しい魔導士]";
		mes "また試したかったら、話しかけてくれ。";
		set CardSetQue,3;
		close;
L_Introduction:
		mes "[妖しい魔導士]";
		mes "１．クリップ１個";
		mes "　　実験段階だからクリップだけだぜ。";
		mes "２．セットするカード";
		mes "　　あんまりいっぱい持たないで欲しいぜ。";
		mes "３．MP";
		mes "　　多ければいいわけじゃないぜ。";
		mes " ";
		mes "準備ができたら言ってくれ！";
		close;
}