//クローンNPC	http://test-ro.net84.net/
//PC_SHOP_POINTを使用してます。MPと言う名前にしてるので変更してください。
//CSVファイルを使用してます。70行目のパスを変更してください。

payo1.gat,105,120,5	script	クローンマスター	981,{
	set '@Skill_lv,getskilllv(225);
	mes "[クローンマスター]";
	mes "MP10くれたら、クローンさせるぜ";
	if(PC_SHOP_POINT < 10 || '@Skill_lv == 0)
		close;
	mes "覚えたいスキルがあるのか？";
	next;
	switch(select("お願い！","やめる")) {
	case 1:
	mes "[クローンマスター]";
	mes "選んでくれ。";
	next;
	set '@level,1;
	set '@row_num,1;
		while (1) {
			for(set '@line, 1; '@row_num < 999; set '@row_num, '@row_num + 1) {
				set '@check, csvread('Clone_db$, '@row_num, 0);
				if ( '@check > '@level )
					continue;
				if ( '@check < '@level )
					break;
				set '@type$['@line], csvread('Clone_db$, '@row_num, 1);
				set '@row['@line], '@row_num;
				set '@line,'@line + 1;
			}
			if ('@level == 1)
				set '@type$['@line],"やめる";
			else
				set '@type$['@line],"戻る";
			cleararray '@type$['@line + 1],"",(128 - '@line);
			if ((select(printarray('@type$)) - 1) == '@line){
				if ('@level == 1)
					close;
				set '@level, 1;
				set '@row_num, 1;
				continue;
			}
			set @menu, @menu - 1;
			set '@row_num, '@row[@menu] + 1;
			set '@check, csvread('Clone_db$, '@row_num, 0);
			if ('@check <= '@level) {
				set '@row, '@row[@menu];
				break;
			}
			set '@level,'@check;
		}
		set '@Skill_name$,csvread('Clone_db$, '@row, 1);
		set '@Skill_id,csvread('Clone_db$, '@row, 2);
		set '@Skill_max,csvread('Clone_db$, '@row, 3);
		if ('@Skill_lv > '@Skill_max)
			set '@Skill_lv,'@Skill_max;
		set PC_SHOP_POINT, PC_SHOP_POINT - 10;
		gmcommand "@cloneskill " + '@Skill_id + " " + '@Skill_lv;
		mes "[クローンマスター]";
		mes "またな。";
		mes " ";
		mes "^0000ff" + '@Skill_name$ + "^000000をLV^0000ff" + '@Skill_lv + "^000000で覚えた！";
		break;
	case 2:
		mes "[クローンマスター]";
		mes "またな。";
	}
	close;
OnInit:
	set 'Clone_db$,"script/original/db/clone_skill.csv";
	end;
}