//==========================================================
//ギルドハウススクリプト　　　　by　あくあ
//==========================================================
prontera.gat,45,63,6	script	ギルドハウス警備員#1	105,{
	if(getgmlevel()) {	//ゲームマスターモード
		mes "[警備員]";
		mes "お勤めご苦労様です。";
		mes "この建物は現在、";
		if($GuildHouse[strnpcinfo(2)] == 0)
			mes "空き家となっています。";
		else {
			mes "ギルド ^FF0000" +getguildname($GuildHouse[strnpcinfo(2)])+ "^000000 の";
			mes "所有物となっています。";
		}
		mes "いかが致しましょう？";
		next;
		switch(select("中に入る","所有ギルドを変える","空き家にする","やめる")) {
		case 1:
			switch(strnpcinfo(2)) {
			case 1: warp "prt_in",44,29; break;
			case 2: warp "prt_in",180,97; break;
			case 3: warp "prt_in",178,55; break;
			case 4: warp "prt_in",172,29; break;
			}
			end;
		case 2:
			mes "[警備員]";
			mes "ギルドハウス" +strnpcinfo(2)+ "の";
			mes "所有ギルドを変更します。";
			mes "新しく所有ギルドとなる";
			mes "対象のギルドIDを入力してください。";
			next;
			input '@num;
			if('@num <= 0) {
				mes "[警備員]";
				mes "取り消しました。";
				close;
			}
			if(getguildname('@num) == "") {
				mes "[警備員]";
				mes "無効なギルドIDです。";
				close;
			}
			if($GuildHouse[strnpcinfo(2)] == '@num) {
				mes "[警備員]";
				mes "既にギルド ^FF0000" +getguildname($GuildHouse[strnpcinfo(2)])+ "^000000 が";
				mes "所有中です。";
				close;
			}
			mes "[警備員]";
			mes "ギルドハウス" +strnpcinfo(2)+ "の所有ギルドを";
			if($GuildHouse[strnpcinfo(2)] != 0)
				mes "ギルド ^FF0000" +getguildname($GuildHouse[strnpcinfo(2)])+ "^000000 から";
			mes "ギルド ^0000FF" +getguildname('@num)+ "^000000 に";
			mes "変更します。";
			mes "本当によろしいですか？";
			next;
			if(select("はい","いいえ")==2) {
				mes "[警備員]";
				mes "取り消しました。";
				close;
			}
			set $GuildHouse[strnpcinfo(2)],'@num;
			mes "[警備員]";
			mes "ギルドハウス" +strnpcinfo(2)+ "の所有ギルドを";
			mes "ギルド ^FF0000" +getguildname($GuildHouse[strnpcinfo(2)])+ "^000000 に";
			mes "変更しました。";
			close;
		case 3:
			if($GuildHouse[strnpcinfo(2)] == 0) {
				mes "[警備員]";
				mes "既に空き家です。";
				close;
			}
			mes "[警備員]";
			mes "ギルド ^FF0000" +getguildname($GuildHouse[strnpcinfo(2)])+ "^000000 が";
			mes "このギルドハウスを所有中です。";
			mes "本当にギルドハウス" +strnpcinfo(2)+ "を";
			mes "空き家にしますか？";
			next;
			if(select("はい","いいえ")==2) {
				mes "[警備員]";
				mes "取り消しました。";
				close;
			}
			set $GuildHouse[strnpcinfo(2)],0;
			mes "[警備員]";
			mes "ギルドハウス" +strnpcinfo(2)+ "を";
			mes "空き家にしました。";
			close;
		case 4:
			close;
		}
	}
	//一般者処理ここから
	if (getcharid(2) == $GuildHouse[strnpcinfo(2)]) {
		switch(strnpcinfo(2)) {
		case 1: warp "prt_in",44,29; break;
		case 2: warp "prt_in",180,97; break;
		case 3: warp "prt_in",178,55; break;
		case 4: warp "prt_in",172,29; break;
		}
		end;
	}
	mes "[警備員]";
	mes "このギルドハウスは";
	if($GuildHouse[strnpcinfo(2)] == 0)
		mes "空き家となっています。";
	else {
		mes "ギルド ^FF0000" +getguildname($GuildHouse[strnpcinfo(2)])+ "^000000 が";
		mes "所有しています。";
	}
	mes "申し訳ありませんが";
	mes "お引取りください。";
	close;
}

prontera.gat,116,266,4	duplicate(ギルドハウス警備員#1)	ギルドハウス警備員#2	105
prontera.gat,196,266,4	duplicate(ギルドハウス警備員#1)	ギルドハウス警備員#3	105
prontera.gat,203,153,1	duplicate(ギルドハウス警備員#1)	ギルドハウス警備員#4	105