//-----------------------------------------------------------------------------
//転職カプラ
//追加職、養子対応、転生一次対応バージョン
//-----------------------------------------------------------------------------
alberta.gat,107,228,4	script	転職カプラ	114,{
	cutin "kafra_04",2;
	if(Class > 6 && Class != Job_TaeKwonBoy) {
		mes "[転職カプラ]";
		mes "あなたはこれ以上転職することが";
		mes "できません。";
		close2;
		cutin "kafra_04",255;
		end;
	}
	if(Class != Job_Novice && Upper == 1) {
		mes "[転職カプラ]";
		mes "ここでは上位二次職の転職は";
		mes "案内できません。";
		mes "担当の者にご相談ください。";
		close2;
		cutin "kafra_04",255;
		end;
	}
	if(getskilllv(1) < 9) {
		mes "[転職カプラ]";
		mes "基本スキルを9にしてきてください。";
		close2;
		cutin "kafra_04",255;
		end;
	}
	if(Class != Job_Novice && JobLevel < 40) {
		mes "[転職カプラ]";
		mes "ジョブレベルを40以上に";
		mes "してきてください。";
		close2;
		cutin "kafra_04",255;
		end;
	}
	if(SkillPoint) {
		mes "[転職カプラ]";
		mes "スキルポイントを全て使い切らないと";
		mes "転職出来ません。";
		close2;
		cutin "kafra_04",255;
		end;
	}
	mes "[転職カプラ]";
	mes "いらっしゃいませ。";
	mes "こちらでは、転職する事が出来ます。";
	mes "転職しますか？";
	next;
	if(select("転職希望する","やめる")==2) {
		mes "[転職カプラ]";
		mes "またのご利用を、お待ちしております。";
		close2;
		cutin "kafra_04",255;
		end;
	}
	mes "[転職カプラ]";
	mes "どの職業に転職しますか？";
	next;
	switch(Class) {
	case Job_Novice:
		setarray '@jobname$,"剣士","マジシャン","アーチャー","アコライト","商人","シーフ","スーパーノービス","テコンキッド","ガンスリンガー","忍者";
		if(Upper == 2)		//養子
			cleararray '@jobname$[6],"",4;	//スパノビ以降は転職不可能
		if(Upper == 1) {	//転生
			switch(OLD_CLASS) {
			case 0:	//OLD_CLASS未採用の時は養子と同様
				cleararray '@jobname$[6],"",4;
				break;
			case 7:
			case 14:	//剣士系
				cleararray '@jobname$[1],"",9;
				break;
			case 9:
			case 16:	//マジシャン系
				cleararray '@jobname$[0],"",1;
				cleararray '@jobname$[2],"",8;
				break;
			case 11:
			case 19:
			case 20:	//アーチャー系
				cleararray '@jobname$[0],"",2;
				cleararray '@jobname$[3],"",7;
				break;
			case 8:
			case 15:	//アコライト系
				cleararray '@jobname$[0],"",3;
				cleararray '@jobname$[4],"",6;
				break;
			case 10:
			case 18:	//商人系
				cleararray '@jobname$[0],"",4;
				cleararray '@jobname$[5],"",5;
				break;
			case 12:
			case 17:	//シーフ系
				cleararray '@jobname$[0],"",5;
				cleararray '@jobname$[6],"",4;
				break;
			}
		}
		switch(select('@jobname$[0],'@jobname$[1],'@jobname$[2],'@jobname$[3],'@jobname$[4],'@jobname$[5],'@jobname$[6],'@jobname$[7],'@jobname$[8],'@jobname$[9],"やめる")) {
		case 1:	//剣士
			unequip;
			jobchange Job_Swordman,Upper;
			break;
		case 2:	//マジシャン
			unequip;
			jobchange Job_Mage,Upper;
			break;
		case 3:	//アーチャー
			unequip;
			jobchange Job_Archer,Upper;
			break;
		case 4:	//アコライト
			unequip;
			jobchange Job_Acolyte,Upper;
			break;
		case 5:	//商人
			unequip;
			jobchange Job_Merchant,Upper;
			break;
		case 6:	//シーフ
			unequip;
			jobchange Job_Thief,Upper;
			break;
		case 7:	//スーパーノービス
			if(BaseLevel < 45) {
				mes "[転職カプラ]";
				mes "スーパーノービスに転職するには";
				mes "ベースレベル45以上が必要です。";
				close2;
				cutin "kafra_04",255;
				end;
			}
			unequip;
			jobchange Job_SuperNovice;
			break;
		case 8:	//テコンキッド
			unequip;
			jobchange Job_TaeKwonBoy;
			break;
		case 9:	//ガンスリンガー
			unequip;
			jobchange Job_Gunslinger;
			break;
		case 10://忍者
			unequip;
			jobchange Job_Ninja;
			break;
		case 11://やめる
			mes "[転職カプラ]";
			mes "またのご利用を、お待ちしております。";
			close2;
			cutin "kafra_04",255;
			end;
		}
		mes "[転職カプラ]";
		mes "転職おめでとうございます！";
		mes "これからのご活躍に期待しております！";
		close2;
		cutin "kafra_04",255;
		end;
	case Job_Swordman:
		setarray '@jobname$,"ナイト","クルセイダー";
		setarray '@jobid,7,14;
		break;
	case Job_Acolyte:
		setarray '@jobname$,"プリースト","モンク";
		setarray '@jobid,8,15;
		break;
	case Job_Mage:
		setarray '@jobname$,"ウィザード","セージ";
		setarray '@jobid,9,16;
		break;
	case Job_Merchant:
		setarray '@jobname$,"ブラックスミス","アルケミスト";
		setarray '@jobid,10,18;
		break;
	case Job_Archer:
		if(Sex) {
			setarray '@jobname$,"ハンター","バード";
			setarray '@jobid,11,19;
		}
		else {
			setarray '@jobname$,"ハンター","ダンサー";
			setarray '@jobid,11,20;
		}
		break;
	case Job_Thief:
		setarray '@jobname$,"アサシン","ローグ";
		setarray '@jobid,12,17;
		break;
	case Job_TaeKwonBoy:
		switch(select("拳聖","ソウルリンカー","やめる")) {
		case 1:
			unequip;
			jobchange Job_StarGladiator;
			break;
		case 2:
			unequip;
			jobchange Job_SoulLinker;
			break;
		case 3://やめる
			mes "[転職カプラ]";
			mes "またのご利用を、お待ちしております。";
			close2;
			cutin "kafra_04",255;
			end;
		}
	}
	switch(select('@jobname$[0],'@jobname$[1],"やめる")) {
	case 1:
		unequip;
		jobchange '@jobid[0],Upper;
		break;
	case 2:
		unequip;
		jobchange '@jobid[1],Upper;
		break;
	case 3://やめる
		mes "[転職カプラ]";
		mes "またのご利用を、お待ちしております。";
		close2;
		cutin "kafra_04",255;
		end;
	}
	mes "[転職カプラ]";
	mes "転職おめでとうございます！";
	mes "これからのご活躍に期待しております！";
	close2;
	cutin "kafra_04",255;
	end;
}