//--------------------------------------------------------
//多色対応版髪型、髪色、服色変更NPC
//多色に対応したカラーパレットを用意すること。
//対応していない色を指定した場合、蔵が表示できずに落ちます
//オリジナル髪型を入れている場合、髪型の変更の時に表示される
//サンプルのグラフィックと食い違いが出るため、使用する事はあまりお勧めできません。
//改造･２次配布等はいくらでもどうぞどうぞ
//			ver1.0		2007/07/21	by RR
//--------------------------------------------------------

//-----------------↓ここは設定必須↓---------------------
prontera.gat,134,215,3	script	スタイリスト	73,{

set @fuku_color,	553;	//服の色数　パレットが用意出来ていないなら７
set @kami_color,	263;	//髪の色数　同上
set @kami_gata,		36;	//髪型の数　同上


//--------------------------------------------------------
//ここは、カラーパレットがその職に対応しているのならコメントアウトする事。

//　カラーパレットが男アサ・男ローグ非対応の場合
   	if (Class == 12) goto X01;
   	if (Class == 17) goto X01;
//　カラーパレットがテコン系非対応の場合
	if (Class == 24) goto X02;
	if (Class == 25) goto X02;
	if (Class == 26) goto X02;
	if (Class == 27) goto X02;
//　カラーパレットが忍者、ガンスリに非対応の場合
	if (Class == 28) goto X02;
	if (Class == 29) goto X02;

//--------------------↑ここまで設定↑--------------------


goto LStart;
//--カラーパレットが非対応の職がある場合
X01:
	if (Sex != 1) goto LStart;
X02:
	mes "[スタイリスト]";
	mes "あらあら、そこのあなた";
	mes "たまには、その髪の色や";
	mes "髪型を変えてみてはどうかしら？";
	next;
	menu "お願いします",Colt,"結構です。",LEnd2;


//--通常対応
LStart:
	mes "[スタイリスト]";
	mes "あらあら、そこのあなた";
	mes "たまには、その洋服の色や";
	mes "髪型や髪の色を変えてみたら？";
	mes "いまなら無料サービス中よ";
	next;
	menu "いいんですか？",L1,"結構です。",LEnd2;
L1:
	mes "[スタイリスト]";
	mes "ええ、もちろん！";
	mes "お洋服と髪型や髪の色";
	mes "どれが、いいかしら？";
	next;
	menu "服の染色で。",Cols,"髪型変更で。",Colt3,"髪染めで。",Colt2,"やっぱりやめます。",LEnd2,;

//--服の染色
Cols:
	mes "[スタイリスト]";
	mes "はい、ありがとう。";
	mes "服の色は +@fuku_color+ 色あるの。";
	mes "何番の色がいいかしら？";
	next;
	menu "" +@fuku_color+ "色からランダム",Colrand,"順番に見ていく",Colnom,"やめておきます･･･",LEndtest,;

Colrand:	mes "[スタイリスト]";
		mes "ではいきますよー";
		mes "服の染色をいたします";
		next;	
		set @FUKU_NUM,rand(0,@fuku_color);
		setlook 7,@FUKU_NUM;
		mes "[スタイリスト]";
		mes "これは " +@FUKU_NUM+ "番 の色ですね";
		mes "またのご利用をお待ちしてます。";
		close;
Colnom:
	mes "[スタイリスト]";
	mes "何番から見始める？";
	mes "" +@fuku_color+ "番の次は0番に戻るからね。";
	set @Colnom_e,1;
	input @FUKU_NUM;
	if(@FUKU_NUM > @fuku_color) goto L_FUKU;
	while(@Colnom_e == 1){
		setlook 7,@FUKU_NUM;
		if (@FUKU_NUM != @fuku_color){set @FUKU_NUM1,@FUKU_NUM +1;}else{set @FUKU_NUM1,0;}
		switch(select(
			"次の色 ("+ @FUKU_NUM1 +"番) を見る","この色 ("+@FUKU_NUM+"番) にする")){
				case 1: set @FUKU_NUM,@FUKU_NUM+1;
					if(@FUKU_NUM==(@fuku_color+1)){set @FUKU_NUM,0;}
					goto Colnom_F;
				case 2: set @Colnom_e,2;
			Colnom_F:
			}
	}
	next;
	mes "[スタイリスト]";
	mes "決まったかな？";
	close;
L_FUKU:
		mes "0〜" +@fuku_color+ "の間で決めてくださいね";
		close;

//ここまで服色
//--------------------------------------------------------
//ここから髪色

//ここは服色非対応の職が飛んでくる所
Colt:
	mes "[スタイリスト]";
	mes "はい、ありがとう。";
	mes "髪型変更と髪染め";
	mes "どちらがいいかしら？";
	next;
	menu "髪型変更で。",Colt3,"髪染めを。",Colt2,"やっぱりやめます。",LEnd2,;	


Colt2:
	mes "[スタイリスト]";
	mes "はい、ありがとう。";
	mes "髪染めの色は８色あるの。";
	mes "何色がいいかしら？";
	next;
	menu "赤色",L_Red,"黄色",L_Yellow,"青色",L_Blue,"緑色",L_Green,"紅色",L_Orange,"紫色",L_Purple,"白色",L_White,"黒色",L_Black,"他の色",L_Coltest,"やめる",LEnd2,;
	close;
	L_Red:
		setlook 6,8;
		goto LEnd1;
	L_Yellow:
		setlook 6,1;
		goto LEnd1;
	L_Blue:
		setlook 6,5;
		goto LEnd1;
	L_Green:
		setlook 6,4;
		goto LEnd1;
	L_Orange:
		setlook 6,3;
		goto LEnd1;
	L_Purple:
		setlook 6,2;
		goto LEnd1;
	L_White:
		setlook 6,6;
		goto LEnd1;
	L_Black:
		setlook 6,7;
		goto LEnd1;
	L_Coltest:
		mes "[スタイリスト]";
	mes "あら、気に入った色が無かった？";
	mes "だったら、まだ実験中の染料から";
	mes "選んでみる？";
	next;
	menu "" +@kami_color+ "色からランダム",Kamirand,"順番に見ていく",Kaminom,"やめておきます･･･",LEndtest,;
Kamirand:	mes "[スタイリスト]";
		mes "ではいきますよー？";
		mes "髪の染色をいたします。";
		next;	
		set @KAMI_NUM,rand(0,@kami_color);
		setlook 6,@KAMI_NUM;
		next;
		mes "[スタイリスト]";
		mes "これは " +@KAMI_NUM+ "番 の色ですね";
		mes "またのご利用をお待ちしてます。";
		close;
Kaminom:
	mes "[スタイリスト]";
	mes "何番から見始めますか？";
	mes "" +@kami_color+ "番の次は0番に戻ります。";
	set @Colnom_e,1;
	input @KAMI_NUM;
	if(@KAMI_NUM > @kami_color) goto L_KAMI;
	while(@Colnom_e == 1){
		setlook 6,@KAMI_NUM;
		if (@KAMI_NUM != @kami_color){set @KAMI_NUM1,@KAMI_NUM +1;}else{set @KAMI_NUM1,0;}
		switch(select(
			"次の色 ("+ @KAMI_NUM1 +"番) を見る","この色 ("+ @KAMI_NUM +"番) にする")){
				case 1: set @KAMI_NUM,@KAMI_NUM +1; 
				if(@KAMI_NUM==(@kami_color+1)){set @KAMI_NUM,0;}goto Colnom_K;
				case 2: set @Colnom_e,2;
			Colnom_K:
			}
	}
	next;
	mes "[スタイリスト]";
	mes "決まったかな？";
	close;
L_KAMI:
		mes "0〜" +@kami_color+ "の間で決めてくださいね";
		close;
LEndtest:
	mes "[スタイリスト]";
	mes "やめちゃうの？残念〜。";
		close;
		end;	
//ここまで髪色
//--------------------------------------------------------
//ここから髪型

Colt3:
	mes "[スタイリスト]";
	mes "何番から見始めますか？";
	mes "" +@kami_gata+ "番の次は1番に戻ります。";
	set @Colnom_e,1;
	input @KAMIGATA_NUM;
	if(@KAMIGATA_NUM > @kami_gata) goto L_KAMIGATA;
	while(@Colnom_e == 1){
		setlook 1,@KAMIGATA_NUM;
		if (@KAMIGATA_NUM != @kami_gata){set @KAMIGATA_NUM1,@KAMIGATA_NUM +1;}else{set @KAMIGATA_NUM1,1;}
		switch(select(
			"次の髪型 ("+ @KAMIGATA_NUM1 +"番) を見る","この髪型 ("+ @KAMIGATA_NUM +"番) にする")){
				case 1: set @KAMIGATA_NUM,@KAMIGATA_NUM +1; 
				if(@KAMIGATA_NUM==(@kami_gata+1)){set @KAMIGATA_NUM,1;}goto Colnom_A;
				case 2: set @Colnom_e,2;
			Colnom_A:
			}
	}
	next;
	mes "[スタイリスト]";
	mes "決まったかな？";
	close;
L_KAMIGATA:
		mes "0〜" +@kami_gata+ "の間で決めてくださいね";
		close;

//髪型処理ここまで

LEnd1:
	next;
	mes "[スタイリスト]";
	mes "まぁ、とてもいいわね。";
	mes "また気分が変わったら";
	mes "いつでも私のところへ";
	mes "来てちょうだい";
	mes "待ってるわね。";
	cutin "hair_f_01",255;
	close;


LEnd2:
	next;
	mes "[スタイリスト]";
	mes "あら･･･やめちゃうの？";
	mes "また、いつでもいらしてね。";
	cutin "hair_f_01",255;
	close;
	end;

L_no:
	next;
	cutin "hair_f_01",255;
	}