//============================説明=========================
//カスタムできる武器を作ってくれるNPCです。
//カードは差せないやつでも差せます。
//どの装備にも差せないカードを作っておくと良いかも？

-.gat,-,-,4	script	カスタマーサービス	923,{

//============================設定=========================

	//武器のIDの設定,0にすると作成不可になります。
	//setarray 'weponnum[番号][0],武器ID,値段;
	setarray 'weponnum[1][0],1202,1000000;//短剣
	setarray 'weponnum[2][0],1102,1000000;//片手剣
	setarray 'weponnum[3][0],1117,1000000;//両手剣
	setarray 'weponnum[4][0],1402,1000000;//片手槍
	setarray 'weponnum[5][0],0,1000000;//両手槍
	setarray 'weponnum[6][0],1302,1000000;//片手斧
	setarray 'weponnum[7][0],1352,1000000;//両手斧
	setarray 'weponnum[8][0],1702,1000000;//弓
	setarray 'weponnum[9][0],1264,1000000;//カタール
	setarray 'weponnum[10][0],1602,1000000;//杖
	setarray 'weponnum[11][0],1502,1000000;//鈍器
	setarray 'weponnum[12][0],0,1000000;//本
	setarray 'weponnum[13][0],1802,1000000;//ナックル
	setarray 'weponnum[14][0],1902,1000000;//楽器
	setarray 'weponnum[15][0],1951,1000000;//鞭

	//マスターカード
	//setarray 'mastercard[番号][0],ID,値段,枚数,サブカードの番号1,サブカードの番号2,サブカードの番号3;
	//番号は0から始めて下さい。
	//枚数に指定した枚数だけ後ろのサブカードの番号のカードが差さります。(最大3枚)
	//ちゃんとお金もかかります。
	//使わない場合は、0または無記入。
	setarray 'mastercard[0][0],4001,1000;
	setarray 'mastercard[1][0],4001,100000,1,1,1,1;
	setarray 'mastercard[2][0],4001,100000,2,1,1,1;
	setarray 'mastercard[3][0],4001,100000,3,1,1,1;
	setarray 'mastercard[4][0],4001,100000,0,1,1,1;

	//サブカード
	//setarray 'subcard[番号][0],ID,値段;
	//番号は0から始めて下さい。
	setarray 'subcard[0][0],4001,50000;
	setarray 'subcard[1][0],4002,60000;

//============================設定終了======================

	mes "["+strnpcinfo(0)+"]";
	mes "いらっしゃい。";
	mes "特殊な武器を作ることがでるよ。";
	mes "どの種類の武器を作るのじゃ？";
	next;

	switch(select("短剣","片手剣","両手剣","片手槍","両手槍","片手斧","両手斧","弓","カタール","杖","鈍器","本","ナックル","楽器","鞭","やめる")){

	case 1: 	set 'wepon,1;	break;
	case 2:		set 'wepon,2;	break;
	case 3:		set 'wepon,3;	break;
	case 4:		set 'wepon,4;	break;
	case 5:		set 'wepon,5;	break;
	case 6:		set 'wepon,6;	break;
	case 7:		set 'wepon,7;	break;
	case 8:		set 'wepon,8;	break;
	case 9:		set 'wepon,9;	break;
	case 10:	set 'wepon,10;	break;
	case 11:	set 'wepon,11;	break;
	case 12:	set 'wepon,12;	break;
	case 13:	set 'wepon,13;	break;
	case 14:	set 'wepon,14;	break;
	case 15:	set 'wepon,15;	break;
	default:	goto L_fin;
	}

	if('weponnum['wepon][0] <= 0){
	mes "["+strnpcinfo(0)+"]";
	mes "今しがたその種類の武器は、";
	mes "作成することができんのじゃ。";
	goto L_end;
	}

	mes "["+strnpcinfo(0)+"]";
	mes "まずは主力になるカード。";
	mes "マスターカードを決めるのじゃ。";
	mes "一枚しか差せないから、";
	mes "気をつけるのじゃぞ。";
	for(set 'i,0; 'mastercard['i][0] != 0 ; set 'i,'i+1) {
		setarray 'mastercardname$['i],getitemname('mastercard['i][0]);
	}
	setarray 'mastercardname$['i],"やめる";
	next;
	if(arrayselect('mastercardname$) == 'i ) goto L_fin;

	set 'master,@menu;
	set 'num,0;

	if('mastercard['master][2] >= 1){
		mes "["+strnpcinfo(0)+"]";
		mes "これにはセットがあるようじゃ。";
		if('mastercard['master][2] >= 1){
			set 'num,'num+1;
			set 'sub[0],'mastercard['master][3];
			if('mastercard['master][2] >= 2){
				mes getitemname('subcard['mastercard['master][3]][0])+"と、";
				} else {
				mes getitemname('subcard['mastercard['master][3]][0])+"じゃ。";
			}
		}
		if('mastercard['master][2] >= 2){
			set 'num,'num+1;
			set 'sub[1],'mastercard['master][4];
			if('mastercard['master][2] >= 3){
				mes getitemname('subcard['mastercard['master][4]][0])+"と、";
				} else {
				mes getitemname('subcard['mastercard['master][4]][0])+"じゃ。";
			}
		}
		if('mastercard['master][2] >= 3){
			set 'num,'num+1;
			set 'sub[2],'mastercard['master][5];
			mes getitemname('subcard['mastercard['master][5]][0])+"じゃ。";
		}
	next;
	}

	mes "["+strnpcinfo(0)+"]";
	mes "次はサブカードじゃ。";
	mes "穴を埋めたり長所を生かすのじゃぞ。";
	next;

	while('num <= 2){

		set 'subnumber,3-'num;
		mes "["+strnpcinfo(0)+"]";
		mes "サブカードは後"+'subnumber+"枚差せるぞ！";
		for(set 'i,0; 'subcard['i][0] != 0 ; set 'i,'i+1) {
			setarray 'subcardname$['i],getitemname('subcard['i][0]);
		}
		setarray 'subcardname$['i],"やめる";
		next;
		if(arrayselect('subcardname$) == 'i ) goto L_fin;

		set 'sub['num],@menu;
		set 'num,'num+1;
	}

	set 'money,'weponnum['wepon][1]+'mastercard['master][1]+'subcard['sub[0]][1]+'subcard['sub[1]][1]+'subcard['sub[2]][1];

	mes "["+strnpcinfo(0)+"]";
	mes getitemname('mastercard['master][0]);
	mes getitemname('subcard['sub[0]][0]);
	mes getitemname('subcard['sub[1]][0]);
	mes getitemname('subcard['sub[2]][0]);
	mes "以上の4枚で"+'money+"Zenyじゃ。";
	mes "よろしいかの？";
	next;
	if(select("はい","いいえ")==2) goto L_fin;
	if(Zeny < 'money) goto L_notmoney;
	if(checkweight('weponnum['wepon][0],1) == 0) goto weightover;

	set Zeny,Zeny-'money;
	getitem2 'weponnum['wepon][0],1,1,0,0,'mastercard['master][0],'subcard['sub[0]][0],'subcard['sub[1]][0],'subcard['sub[2]][0];

	mes "["+strnpcinfo(0)+"]";
	mes "ありがとう。";
	mes "また来たくるといいの。";
	goto L_end;
L_notmoney:
	mes "["+strnpcinfo(0)+"]";
	mes "お金が無いようじゃ。";
	mes "また来たくるといいの。";
	goto L_end;
weightover:
	mes "["+strnpcinfo(0)+"]";
	mes "持てない様じゃぞ。";
	mes "また来たくるといいの。";
	goto L_end;
L_fin:
	mes "["+strnpcinfo(0)+"]";
	mes "やめるのじゃな。";
	mes "また来るといい。";
L_end:
	close;
}