prt_in.gat,38,104,6	script	同姓用結婚式場	95,{
	if($@marry==2 && strcharinfo(0) == $@nameB$ ) { callfunc "marriage2"; }
	if($@marry==1 || $@marry == 2) {
		mes "[シスター]";
		mes "今、式の途中なの。";
		mes "焦らないで少し待ってなさい。";
		close;
	}
	getpartymember getcharid(1);
	for(set $@i,0; $@i<2; set $@i,$@i+1) {
		if($@partymembername$[$@i] != strcharinfo(0))
			set '@another$,$@partymembername$[$@i];		//PT内に居る相手の名前を一時保存
	}
	if($@partymembercount != 2 || (Sex != readparam(21,'@another$))) {
		mes "[シスター]";
		mes "結婚したいのなら、式を挙げる二人で";
		mes "パーティーを組んで来なさい。";
		mes "後、異性同士の普通の結婚は国王に頼んで貰えるかしら？";
		close;
	}
	if(PartnerID > 0) {
		mes "[シスター]";
		mes "貴方は結婚済みのようね。";
		mes "誰かをお祝いに来たのかしら？";
		close;
	}
	if(Upper == 2) {
		mes "[シスター]";
		mes "貴方は少し若すぎるようね。";
		mes "大人になってからもう一度来なさい。";
		close;
	}
	if(Zeny<1000000) { callfunc "zeny_error"; }
	if(BaseLevel<45) {
		mes "[シスター]";
		mes "貴方はもう少し自分を磨いてから来た方がいいわね。";
		mes "自分をも護れないのに、相手を護るなんて出来ないのよ。";
		mes "しっかりと頑張りなさい。";
		close;
	}
	mes "[闇の結婚屋]";
	mes "ここは、性別を超えた愛を形にする為の";
	mes "非公式の結婚式場よ。";
	mes "結婚する場合はLvが^3377FF45^000000以上で、尚且つ^3377ff1Mzeny^000000必要よ。";
	next;
	mes "[闇の結婚屋]";
	mes "後、新郎役から話しかけて貰わなきゃきちんと挙げられないの。";
	mes "だから、まず初めにどちらからか決めてから依頼してね。";
	mes "あ、それと性転換した直後は控えるようにして下さるかしら。";
	next;
	mes "[シスター]";
	mes "なんだか、うまく動かない事が多くなっちゃうから。";
	mes "それと、30分以内に結婚出来なきゃキャンセルするわよ。";
	mes "で、貴方は結婚を申し込みに来たのかしら？";
	next;
	if(select("そうです","違います")==2){
		mes "[シスター]";
		mes "あら、違うの？";
		mes "誰かをお祝いに来たのかしら。";
		close;
	}
	set $@marry,1;				//結婚フラグＯＮ
	initnpctimer;				//時間制限開始
	mes "[シスター]";
	mes "貴方の一番大事な人…";
	mes "その名前を教えて下さるかしら？";
	next;
	input $@nameB$;
	if (getcharid(0,$@nameB$) < 0){ callfunc "error"; }
	mes "[シスター]";
	mes "次は、貴方のパートナーから話しかけて貰えるかしら。";
	set $@marry,2;
	close;
OnTimer1800000:					//30分チェック
	announce "シスター: 返事が遅いわ……次の式を行いましょう。",0x10;
	set $@marry,0;
	end;
}
function	script	marriage2	{	//2人目
	if(Zeny<1000000) { callfunc "zeny_error"; }
	mes "[シスター]";
	mes "貴方がパートナーね。一応、PTの確認をさせて貰うわよ。";
	next;
	getpartymember getcharid(1);
	if ($@partymembercount != 2){ callfunc "error"; }
	mes "[シスター]";
	mes "貴方の一番大事な人…";
	mes "その名前を教えて下さるかしら？";
	next;
	input $@nameA$;
	if (getcharid(0,$@nameA$) < 0){ callfunc "error"; }
	mes "[シスター]";
	mes "うん…";
	mes "大丈夫なようね。";
	mes "簡単な儀式だったけれど、これで二人は結ばれたわ。";
	mes "本当におめでとう、幸せになりなさい。";
	next;
	set $@dummy,marriage($@nameA$);
	if(Sex ==0){ set @item_id,2635; }else{ set @item_id,2634; }
	getitem @item_id,1,0;
	getitem @item_id,1,0,getcharid(3,$@nameA$);
	set $@marry,0;
	set Zeny,Zeny-1000000;
	gmcommand "@charzeny -1000000 "+$@nameA$;
	wedding;
	sc_start SC_WEDDING,3600000,0;
	sc_start SC_WEDDING,3600000,0,getcharid(3,$@nameA$);
	announce "【同姓婚情報】" +$@nameA$+"と"+$@nameB$+"、新たなる夫婦の誕生をここに祝福しよう！",0x10;
	announce "[シスター] : 二人とも…必ず幸せになりなさい…。",0x08;
	stopnpctimer;
	close;
	}
function	script	error	{	//エラー用
	mes "[シスター]";
	mes "まだ準備が終わってないようね。";
	mes "準備が終わってからもう一度来なさい。";
	set $@marry,0;
	close;
}
function	script	zeny_error	{	//所持金チェック
	mes "[シスター]";
	mes "少し所持金が足りないようね。";
	mes "きちんと貯めてからいらっしゃい。。";
	set $@marry,0;
	close;
	}