/*==============================================================================
	NPCID番号確認用
--------------------------------------------------------------------------------
NPC、MOBのグラフィックを確認するための開発用工具です。
公開中の鯖に設置するといくつの問題が起こります。
クリックできないNPCになったり、重力エラーが起こる
可能性もありますが、一度画面から離れれば元に戻ります。
--------------------------------------------------------------------------------*/
prontera.gat,167,125,4 script グラフィック確認#0 105,{

	//---------- 設定 ----------
	//対応可能な最大値(デフォルト：1999)
	set '@max,1999;
	//-------- 設定終了 --------

	if ('num[1] == 0) {
		setarray 'num,0,1,2,3,4,5,6,7,8,9;
	}
	if (getgmlevel() < 95) {
		mes "[？？？？]";
		mes "ゲームマスター専用機能です。";
		close;
	}
	if (strnpcinfo(2) != "0") {
		mes "[？？？？]";
		mes "われらは隊長の命令に従う。";
		close;
	}

	set 'class,105;
	donpcevent "::OnNIC_C_CHANGE";
	mes "[変装隊長]";
	mes "こちらはNPC、MOBのグラフィックを";
	mes "10体単位で確認することができます。";
	next;
	switch(select("利用する","やめる")) {
	case 1:
		while(1) {	//実行ループ
			set '@x,'class-('class%10);
			mes "[変装隊長]";
			mes "表示中グラフィックの番号は";
			mes "^0000F0"+'class+"^000000〜^0000F0"+('class+9)+"^000000です。";
			next;
			switch(select(('@x+10)+"-"+('@x+19),('@x-10)+"-"+('@x-1),"ID指定","帰る")) {
			case 1:
				set '@num,'@x+10;
				break;
			case 2:
				set '@num,'@x-10;
				break;
			case 3:
				input '@num;
				break;
			default:
				goto L_CANCEL;
				break;
			}

			//IDチェック、表示
			while(1) {	//数値入力ループ
				if ('@num < 0) break;
				if (	(@menu == 3 && '@num >= 46 && '@num <= 129) ||
					(@menu < 3 && '@num >= 40 && '@num <= 129) ||
					('@num >= 700 && '@num <= '@max)) {
					set 'class,'@num;
					donpcevent "::OnNIC_C_CHANGE";
				} else {
					mes "[変装隊長]";
					mes "未対応番号です。";
					next;
				}
				if (@menu != 3) break;
				set '@x,'class-('class%10);
				mes "[変装隊長]";
				mes "表示中グラフィックの番号は";
				mes "^0000F0"+'class+"^000000〜^0000F0"+('class+9)+"^000000です。";
				mes "やめる場合は負数を入れてください。";
				next;
				input '@num;
			}		//数値入力ループ
		}		//実行ループ
		break;
	default:
		break;
	}
L_CANCEL:
	mes "[変装隊長]";
	mes "さようなら。";
	close;
OnNIC_C_CHANGE:
	classchange ('class+'num[strnpcinfo(2)]),0;
	end;
}

prontera.gat,170,125,4 duplicate(グラフィック確認#0)	ＩＤ番号＋１#1 105,{}
prontera.gat,173,125,4 duplicate(グラフィック確認#0)	ＩＤ番号＋２#2 105,{}
prontera.gat,176,125,4 duplicate(グラフィック確認#0)	ＩＤ番号＋３#3 105,{}
prontera.gat,179,125,4 duplicate(グラフィック確認#0)	ＩＤ番号＋４#4 105,{}
prontera.gat,167,121,4 duplicate(グラフィック確認#0)	ＩＤ番号＋５#5 105,{}
prontera.gat,170,121,4 duplicate(グラフィック確認#0)	ＩＤ番号＋６#6 105,{}
prontera.gat,173,121,4 duplicate(グラフィック確認#0)	ＩＤ番号＋７#7 105,{}
prontera.gat,176,121,4 duplicate(グラフィック確認#0)	ＩＤ番号＋８#8 105,{}
prontera.gat,179,121,4 duplicate(グラフィック確認#0)	ＩＤ番号＋９#9 105,{}

/*==============================================================================
	単体稼動版
--------------------------------------------------------------------------------*/
prontera.gat,144,125,4 script グラフィック確認（単体） 105,{

	//---------- 設定 ----------
	//対応可能な最大値(デフォルト：1999)
	set '@max,1999;
	//-------- 設定終了 --------

	if (getgmlevel() < 95) {
		mes "[？？？？]";
		mes "ゲームマスター専用機能です。";
		close;
	}
	set '@class,105;
	classchange '@class,0;
	mes "[変装隊員(仮)]";
	mes "こちらはNPC、MOBのグラフィックを";
	mes "１体ずつで確認することができます。";
	next;
	switch(select("利用する","やめる")) {
	case 1:
		while(1) {	//実行ループ
			mes "[変装隊員(仮)]";
			mes "表示中グラフィックの番号は";
			mes "^0000F0"+'@class+"^000000です。";
			next;
			switch(select("次のID","前のID","ID指定","帰る")) {	//ID指定
			case 1:
				set '@num,'@class+1;
				break;
			case 2:
				set '@num,'@class-1;
				break;
			case 3:
				input '@num;
				break;
			default:
				goto L_CANCEL;
				break;
			}	//ID指定

			//IDチェック、表示
			while(1) {	//数値入力ループ
				if ('@num < 0) break;
				if (	('@num >= 46 && '@num <= 129) ||
					('@num >= 700 && '@num <= '@max)) {
					set '@class,'@num;
					classchange '@class,0;
				} else {
					mes "[変装隊員(仮)]";
					mes "未対応番号です。";
					next;
				}
				if (@menu != 3) break;
				set '@x,'@class-('@class%10);
				mes "[変装隊員(仮)]";
				mes "表示中グラフィックの番号は";
				mes "^0000F0"+'@class+"^000000です。";
				mes "やめる場合は負数を入れてください。";
				next;
				input '@num;
			}		//数値入力ループ
		}		//実行ループ
		break;
	default:
		break;
	}
L_CANCEL:
	mes "[変装隊員(仮)]";
	mes "さようなら。";
	close;
}