//==============================================================================
// コスプレNPC                                     by はにわ 2009/08/16 ver1.10
//==============================================================================
// 概要
// 見た目をモンスターにするNPCです
//
// 仕組み
// 髪型をモンスターグラフィックに、髪色を0番に、服色を透過させます
// 元に戻すときはランダムの既存髪型に変えて、服の色を0番にします
//
// 必要なもの
// １．コスプレ用ACT/SPR　→　髪型として追加
// ２．全色透過パレット　→　服色として追加
// コスプレ用ACT/SPRは一緒にアップしたスクリプトで作るか自作して下さい
// 全色透過パレットはほにゃららか自作して下さい
// ACT/SPRおよびパレットを追加する方法はネットで調べて下さい
//==============================================================================
prontera.gat,155,194,3	script	コスプレ店員	861,{
	
	//---------------------------------------------------------------
	// 設定
	//---------------------------------------------------------------
	
	//コスプレの数
	set 'kosu_cnt,12;
	
	//コスプレ時の服色(服の全透過パレットを追加し、その番号を指定する)
	set 'body_color_clear,5;
	
	//コスプレ返却後の髪型候補数(普段使用している髪型の数を指定する)
	set 'hair_type_def,27;
	
	//料金
	set 'pay_zeny,10;
	
	//---------------------------------------------------------------
	// メイン処理
	//---------------------------------------------------------------
	
	mes "[コスプレ店員]";
	mes "コスプレ店へようこそ。";
	mes "今日はどんなご用事？";
	next;
	
	switch (select("コスプレ衣装を借りる","コスプレ衣装を返す","なんでもない")) {
	case 1:
		mes "[コスプレ店員]";
		mes "衣装の貸し出しを希望するのね。";
		mes "料金は^FF0000" + 'pay_zeny + "zeny^000000よ。";
		mes "何を貸し出すかは秘密だけれど";
		mes "それでもいい？";
		mes "え？なんで秘密なのかって？";
		mes "そっちの方が楽しそうじゃない。";
		next;
		
		switch (select("わかった、いいよ","やっぱりやめとく")) {
		case 1:
			if (zeny >= 'pay_zeny) {
				//料金支払い
				set zeny,zeny-'pay_zeny;
				mes "[コスプレ店員]";
				mes "じゃあ着せちゃうわね。";
				mes "そーれっと。";
				next;
				//コスプレを決定(今のコスプレ以外のものが選ばれるまで最大5回ループ)
				for(set 'lcnt,1;'lcnt <= 5;set 'lcnt,'lcnt+1) {
					set 'hair_type_kosu,rand('kosu_cnt)+1+'hair_type_def;
					if ('hair_type_kosu != getlook(1)) {
						break;
					}
				}
				//髪型をランダム(コスプレ)に変更する
				setlook 1,'hair_type_kosu;
				//髪色を基本色に変更する
				setlook 6,0;
				//服色を全色透過に変更する
				setlook 7,'body_color_clear;
				
				mes "[コスプレ店員]";
				mes "うん。よく似合ってるわ。";
				mes "それじゃ返す時はまた来てね。";
				close;
			} else {
				mes "[コスプレ店員]";
				mes "残念だけどお金が足りないわ。";
				mes "お金が貯まったらまた来てね。";
				close;
			}
		
		case 2:
			mes "[コスプレ店員]";
			mes "あらそう？残念ね。";
			mes "それじゃまた来てね。";
			close;
		}
	
	case 2:
		//コスプレしているかどうかチェック
		set 'kami_gata_now,getlook(1);
		if ('kami_gata_now > 'hair_type_def) {
			mes "[コスプレ店員]";
			mes "衣装の返却を希望するのね。";
			mes "じゃあ脱がせるわね。";
			next;
			//髪型をランダムに、服装をデフォルトに変更する
			setlook 1,rand('hair_type_def)+1;
			setlook 7,0;
			mes "[コスプレ店員]";
			mes "はい、お疲れ様でした。";
			mes "髪が乱れちゃっているみたいだから";
			mes "後でコーディネイターにみてもらってね。";
			mes "じゃ、またねー。";
			close;
		} else {
			mes "[コスプレ店員]";
			mes "あなた衣装持ってないわよ。";
			mes "まさか、どこかに脱ぎ捨てて来た訳じゃ";
			mes "ないわよね。";
			close;
		}
	
	case 3:
		mes "[コスプレ店員]";
		mes "あらそう？";
		mes "気が向いたらまた来てね。";
		close;
	}
}