//==============================================================================
// RagnarokOnline Original AttackEvent Script Ver1.0   by Blaze
//==============================================================================
sec_pri.gat,43,46,4	script	世界の支配者	735,{
	if(getgmlevel() < 1) {	//GMじゃなかったら
		mes "[世界の支配者]";
		mes "…………";
		mes "何だ、君は？";
		mes "君のような力のない者に";
		mes "興味はない……";
		close;
	}
	if('flag) {	//イベント発動中
		mes "[世界の支配者]";
		mes "今、モンスターが街を襲撃中だ。";
		mes "この力は同時に使える程、";
		mes "簡単なものじゃないんだ。";
		mes "もう少し待ってくれ。";
		close;
	}
	mes "[世界の支配者]";
	mes "ようこそ。";
	mes "私は世界を操る力を持つ者。";
	mes "街をモンスターの集団に";
	mes "襲わせることだってできる。";
	mes "少しだけ力を見せてやろうか？";
	next;
	switch(select("襲撃イベント発動","設定を見る","設定を変える","やめる")) {
	case 1:
		mes "[世界の支配者]";
		mes "まずは襲撃する街を選んでくれ。";
		next;
		switch(select("プロンテラ","モロク","ゲフェン","フェイヨン","アルベルタ","イズルード","アルデバラン","ルティエ","コモド","ジュノー",
			"アマツ","コンロン","ウンバラ","ニブルヘイム","龍之城","ジャワイ","アユタヤ","アインブロック","アインベフ","リヒタルゼン","フィゲル","ラヘル")) {
		case 1: set 'town$,"prontera"; set 'town_name$,"プロンテラ"; break;
		case 2: set 'town$,"morocc"; set 'town_name$,"モロク"; break;
		case 3: set 'town$,"geffen"; set 'town_name$,"ゲフェン"; break;
		case 4: set 'town$,"payon"; set 'town_name$,"フェイヨン"; break;
		case 5: set 'town$,"alberta"; set 'town_name$,"アルベルタ"; break;
		case 6: set 'town$,"izlude"; set 'town_name$,"イズルード"; break;
		case 7: set 'town$,"aldebaran"; set 'town_name$,"アルデバラン"; break;
		case 8: set 'town$,"xmas"; set 'town_name$,"ルティエ"; break;
		case 9: set 'town$,"comodo"; set 'town_name$,"コモド"; break;
		case 10: set 'town$,"yuno"; set 'town_name$,"ジュノー"; break;
		case 11: set 'town$,"amatsu"; set 'town_name$,"アマツ"; break;
		case 12: set 'town$,"gonryun"; set 'town_name$,"コンロン"; break;
		case 13: set 'town$,"umbala"; set 'town_name$,"ウンバラ"; break;
		case 14: set 'town$,"niflheim"; set 'town_name$,"ニブルヘイム"; break;
		case 15: set 'town$,"louyang"; set 'town_name$,"龍之城"; break;
		case 16: set 'town$,"jawaii"; set 'town_name$,"ジャワイ"; break;
		case 17: set 'town$,"ayothaya"; set 'town_name$,"アユタヤ"; break;
		case 18: set 'town$,"einbroch"; set 'town_name$,"アインブロック"; break;
		case 19: set 'town$,"einbech"; set 'town_name$,"アインベフ"; break;
		case 20: set 'town$,"lighthalzen"; set 'town_name$,"リヒタルゼン"; break;
		case 21: set 'town$,"hugel"; set 'town_name$,"フィゲル"; break;
		case 22: set 'town$,"rachel"; set 'town_name$,"ラヘル"; break;
		}
		mes "[世界の支配者]";
		mes "襲撃する街：" +'town_name$;
		mes "モンスター数：" +'conf_mob+ "匹";
		mes "襲撃時間：" +'conf_time+ "分";
		mes "ボスモンスター：" +('conf_boss? 'conf_boss+"匹": "なし");
		mes " ";
		mes "この設定で襲撃するか？";
		next;
		if(select("はい","いいえ")==2)
			break;
		if('flag) {
			mes "[世界の支配者]";
			mes "……ん？";
			mes "うまく力が使えなかったみたいだ。";
			mes "すまないな。";
			close;
		}
		mes "[世界の支配者]";
		mes 'town_name$+ "に";
		mes "モンスターの集団を向かわせたぞ。";
		mes "ククク……";
		set 'flag,1;
		set 'mob,'conf_mob;
		set 'time,'conf_time;
		set 'boss,'conf_boss;
		donpcevent "世界の支配者::OnStart";
		close;
	case 2:
		mes "<<現在の設定>>";
		mes "モンスター数：" +'conf_mob+ "匹";
		mes "襲撃時間：" +'conf_time+ "分";
		mes "ボスモンスター：" +('conf_boss? 'conf_boss+"匹": "なし");
		close;
	case 3:
		mes "[世界の支配者]";
		mes "力の加減を変えてやろう。";
		mes "どの設定を変えるんだ？";
		next;
		switch(select("モンスターの数","襲撃の時間","ボスモンスター","やめる")) {
		case 1:
			mes "<<現在の設定>>";
			mes "モンスター数：" +'conf_mob+ "匹";
			mes " ";
			mes "この数だけモンスターが出現します。";
			mes "何匹に変更しますか？";
			next;
			input '@num;
			if('@num <= 0) {
				mes "取り消しました。";
				close;
			}
			set 'conf_mob,'@num;
			mes "[世界の支配者]";
			mes "襲わせるモンスターの数を";
			mes '@num+ "匹に変更したぞ。";
			close;
		case 2:
			mes "<<現在の設定>>";
			mes "襲撃時間：" +'conf_time+ "分";
			mes " ";
			mes "この時間を超えるとイベント終了です。";
			mes "何分に変更しますか？（分単位）";
			next;
			input '@num;
			if('@num <= 0) {
				mes "取り消しました。";
				close;
			}
			set 'conf_time,'@num;
			mes "[世界の支配者]";
			mes "モンスターが襲撃する時間を";
			mes '@num+ "分に変更したぞ。";
			close;
		case 3:
			mes "<<現在の設定>>";
			mes "ボスモンスター：" +('conf_boss? 'conf_boss+"匹": "なし");
			mes " ";
			mes "モンスターを全て倒すと出現する";
			mes "ボスモンスターの数です。";
			mes "何匹に変更しますか？";
			mes "（0にするとボスが出現しません）";
			next;
			input '@num;
			if('@num < 0) {
				mes "取り消しました。";
				close;
			}
			set 'conf_boss,'@num;
			mes "[世界の支配者]";
			if('@num == 0) {
				mes "ボスモンスターを";
				mes "出現しないようにしたぞ。";
				close;
			}
			mes "ボスモンスターの数を";
			mes '@num+ "匹に変更したぞ。";
			close;
		case 4:
			break;
		}
		break;
	case 4:
		break;
	}
	mes "[世界の支配者]";
	mes "私の力を見たかったら";
	mes "また来るがいい。";
	close;
OnInit:
//	**********↓ 初期設定 ↓**********

//	召喚するモンスターの数（初期値: 50匹）
	set 'conf_mob,50;

//	イベントの時間（分単位、初期値: 10分）
	set 'conf_time,10;

//	ボスモンスターの数（0にするとボスイベントなし、初期値: 1）
	set 'conf_boss,1;

//	**********↑ ここまで ↑**********
//	※ゲーム中でも設定を変更できます（要：毎回設定）
	end;
OnStart:
	announce "ミッドガルド放送局 : 大変です！　現在" +'town_name$+ "にモンスターの集団が向かっています！",8;
	sleep 5000;
	announce "ミッドガルド放送局 : " +'town_name$+ "にいる方は非難をしてください！　繰り返します、非難してください！",8;
	sleep 30000;
	mapannounce 'town$+".gat","-ギイギイーッ……グルルゥーッ、ギイギイギィーッ、グアァーッ!!-",0,0xFF0000;
	areamonster 'town$+".gat",0,0,500,500,"--ja--",-1,'mob,"Attack#"+'town$+"::OnKilled";
	initnpctimer;
	sleep 5000;
	mapannounce 'town$+".gat","ミッドガルド放送局 : モンスターが襲撃してきました！　" +'town_name$+ "住民の皆さん気をつけてください！",0;
	end;
OnKilled:
	set 'mob,'mob-1;
	if('mob == 0 && 'boss != 0) {
		mapannounce 'town$+".gat","-ギイギイーッ……グルルゥーッ、ギイギイギィーッ、グアァーッ!!-",0,0xFF0000;
		areamonster 'town$+".gat",0,0,500,500,"--ja--",-3,'boss,"Attack#"+'town$+"::OnKilled";
		set 'mob,'boss;
		set 'boss,0;
		sleep 5000;
		mapannounce 'town$+".gat","ミッドガルド放送局 : ボスモンスターが出現しました！　気をつけてください！",0;
	}
	else if('mob == 0)
		donpcevent "世界の支配者::OnEnd";
	end;
OnEnd:
	stopnpctimer;
	killmonster 'town$+".gat","Attack#"+'town$+"::OnKilled";
	mapannounce 'town$+".gat","ミッドガルド放送局 : モンスターは全滅したようです！　" +'town_name$+ "住民の皆さんご安心ください。",0;
	set 'mob,0;
	set 'time,0;
	set 'boss,0;
	set 'town$,0;
	set 'town_name$,0;
	set 'flag,0;
	end;
OnTimer60000:
	set 'time,'time-1;
	if('time == 0) {
		stopnpctimer;
		killmonster 'town$+".gat","Attack#"+'town$+"::OnKilled";
		mapannounce 'town$+".gat","ミッドガルド放送局 : モンスターは去っていきました。　" +'town_name$+ "住民の皆さんご安心ください。",0;
		set 'mob,0;
		set 'boss,0;
		set 'town$,0;
		set 'town_name$,0;
		set 'flag,0;
		end;
	}
	initnpctimer;
	end;
}

//ダミーイベント
sec_pri.gat,0,0,0	script	Attack#dummy	-1,{
OnKilled:
	donpcevent "世界の支配者::OnKilled";
	end;
}

prontera.gat,0,0,0	duplicate(Attack#dummy)	Attack#prontera	-1
morocc.gat,0,0,0	duplicate(Attack#dummy)	Attack#morocc	-1
geffen.gat,0,0,0	duplicate(Attack#dummy)	Attack#geffen	-1
payon.gat,0,0,0		duplicate(Attack#dummy)	Attack#payon	-1
alberta.gat,0,0,0	duplicate(Attack#dummy)	Attack#alberta	-1
izlude.gat,0,0,0	duplicate(Attack#dummy)	Attack#izlude	-1
aldebaran.gat,0,0,0	duplicate(Attack#dummy)	Attack#aldebaran	-1
xmas.gat,0,0,0		duplicate(Attack#dummy)	Attack#xmas	-1
comodo.gat,0,0,0	duplicate(Attack#dummy)	Attack#comodo	-1
yuno.gat,0,0,0		duplicate(Attack#dummy)	Attack#yuno	-1
amatsu.gat,0,0,0	duplicate(Attack#dummy)	Attack#amatsu	-1
gonryun.gat,0,0,0	duplicate(Attack#dummy)	Attack#gonryun	-1
umbala.gat,0,0,0	duplicate(Attack#dummy)	Attack#umbala	-1
niflheim.gat,0,0,0	duplicate(Attack#dummy)	Attack#niflheim	-1
louyang.gat,0,0,0	duplicate(Attack#dummy)	Attack#louyang	-1
jawaii.gat,0,0,0	duplicate(Attack#dummy)	Attack#jawaii	-1
ayothaya.gat,0,0,0	duplicate(Attack#dummy)	Attack#ayothaya	-1
einbroch.gat,0,0,0	duplicate(Attack#dummy)	Attack#einbroch	-1
einbech.gat,0,0,0	duplicate(Attack#dummy)	Attack#einbech	-1
lighthalzen.gat,0,0,0	duplicate(Attack#dummy)	Attack#lighthalzen	-1
hugel.gat,0,0,0		duplicate(Attack#dummy)	Attack#hugel	-1
rachel.gat,0,0,0	duplicate(Attack#dummy)	Attack#rachel	-1