//====================================================================
// RagnarokOnline Original Soul Script Ver1.1   by Blaze
//====================================================================
prontera.gat,128,217,5	script	彷徨う魂#soul	802,{
	emotion 9;
	mes "[彷徨う魂]";
	mes "ううう……";
	mes "ここは……どこ……";
	mes "私にはまだやるべきことが……";
	next;
	mes "[彷徨う魂]";
	mes "頼む……";
	mes "お前の体を……";
	mes "少しの間だけ貸してくれないか……？";
	next;
	if(select("いいよ","絶対ダメ")==2) {
		emotion 28;
		mes "[彷徨う魂]";
		mes "悪いことはしない……";
		mes "頼む……！";
		close;
	}
	switch(Class) {
	case 7: set '@soul,250; break;	//ナイト
	case 8: set '@soul,252; break;	//プリースト
	case 9: set '@soul,251; break;	//ウィザード
	case 10: set '@soul,256; break;	//ブラックスミス
	case 11: set '@soul,257; break;	//ハンター
	case 12: set '@soul,255; break;	//アサシン
	case 14: set '@soul,258; break;	//クルセイダー
	case 15: set '@soul,245; break;	//モンク
	case 16: set '@soul,247; break;	//セージ
	case 17: set '@soul,254; break;	//ローグ
	case 18: set '@soul,244; break;	//アルケミスト
	case 19:			//バード
	case 20: set '@soul,253; break;	//ダンサー
	case 23: set '@soul,249; break;	//スーパーノービス
	case 25: set '@soul,246; break;	//拳聖
	case 27: set '@soul,258; break;	//ソウルリンカー
	default:
		if(Upper && Class < 7)
			 set '@soul,259; break;
	}
	if('@soul == 0) {
		emotion 28;
		mes "[彷徨う魂]";
		mes "ううう……";
		mes "だめだ……";
		mes "お前の体では私の望むことを";
		mes "叶えられそうにない……";
		close;
	}
	mes "[彷徨う魂]";
	mes "ありがとう。";
	mes "では力を抜いて……";
	mes "そう……それでいい……";
	next;
	emotion 9;
	disablenpc;
	initnpctimer;
	gmcommand "@misceffect 424";
	gmcommand "@misceffect 503";
	sc_start '@soul,600000,1;
	mes "[彷徨う魂]";
	mes "少しの間だけお邪魔させてもらうよ。";
	mes "何、普段通り動いてもらって構わん。";
	mes "私の力を少しだけ貸してあげよう……";
	close;
OnTimer600000:
	enablenpc;
	end;
}