//================================================
//	服髪色・髪型変更NPC
//------------------------------------------------
//髪型と服の色の最大値を設定可能に変更。
//髪の色を染める部分を整形。
//性別転換の使用不可をデフォルトに変更。
//------------------------------------------------
//転職前に服の色を戻せと書いたところで、説明文を
//読まない人には意味無いため、♂シーフを服染め不可に
//しました。どうしても制限条件を解除したい場合、
//服染め用のパレットを追加するか転職NPCを弄って
//♂アサ・ローグの服の色を元に戻すような命令を
//追加したほうがいいと思います。
//------------------------------------------------
//性転換には回避不能な問題があるため、
//説明文を補足、変更してみました。
//------------------------------------------------
//設置例は最下部にあります。
//------------------------------------------------
-	script	coordinator	722,{

	//--------設定---------
	//髪型の最大値、デフォルトは23
set '@hair,	23	;
	//服の色の最大値、デフォルトは4
set '@cloth,	4	;
	//--------終了---------

	cutin "wedding_marry01",2;
	mes "[コーディネーター]";
	mes "本日のご用件は何でしょうか？";
	mes "尚、転職時には服の色を";
	mes "デフォルトに戻してください。";
	mes "スパノビ以外の拡張職と";
	mes "男性のシーフ系の職業は";
	mes "服の色を染めません。";
	next;
	menu	"髪の色を染める",Lhairc,"髪型を変える",Lhairs,"服の色を染める",Lclothc,
//		"性転換",Lchangesex,
		"やめる",Lexit;

	//性転換による重力エラー、スキルポイント損失等問題は
	//回避不可能のため、デフォルトを不可にします。

Lhairc:
	mes "[コーディネーター]";
	mes "何色に染めますか？";
	next;
	set '@select,select("デフォルト","黄","紫","褐","緑","青","白","黒","赤");
	setlook 6,'@select-1;
	goto Lexit;

Lhairs:
	mes "[コーディネーター]";
	mes "どの髪型にしますか？";
	mes "種類は0〜"+'@hair+"です";
	mes "番号を半角で入力して下さい。";
	input @hairstyle;
	if (@hairstyle < 0 || @hairstyle > '@hair) goto MISS;
	setlook 1,@hairstyle;
	goto Lexit;
Lclothc:

	//デフォルトだとスパノビ以降の職は服を染めません。
	if (Class > 23) goto Lfail;

	//♂シーフ、アサシンは同上
	if (Sex == 1 && (Class == 12 || Class == 17)) goto Lfail;

	//♂シーフは一応可能だけど、
	//服色を染めたまま転職したらアウトなので
	//デフォルトを不可にします。
	if (Sex == 1 && Class == 6) goto Lfail;

	mes "[コーディネーター]";
	mes "0〜"+'@cloth+"の数字を半角で入れて下さい。";
	input @clothcolor;
	if (@clothcolor < 0 || @clothcolor > '@cloth) goto MISS;
	setlook 7,@clothcolor;
	next;
	goto Lexit;
Lfail:
	//念のために服色をデフォルトに
	//設定しなおすのチェックを入れます。
	//すでに問題が起こられたキャラは
	//この分岐を入る時点で直れる。
	//要らないなら削除してください。
	setlook 7,0;

	mes "[コーディネーター]";
	mes "申し訳ありませんが、";
	mes "あなたの服を染めることはできません。";
	goto L_CLOSE;

Lchangesex:
	mes "[コーディネーター]";
	mes "性転換する前の注意事項ですが･･･";
	mes "^CO0000同じ垢^000000の^0000FFダンサー・バード系";
	mes "キャラ^000000は^C00000必ず^000000^0000FF全ての装備品を外して";
	mes "スキルをリセットしておいて下さい^000000。";
	mes "場合によって^C00000スキルポイントの損失^C00000か";
	mes "^C00000二度とログインできなくなります^000000。";
	next;
	if(select("知るか。","わかりました。")==1) goto Lfail2;
	mes "[コーディネーター]";
	mes "^CO0000♀垢^000000の場合、^0000FFシーフ系キャラの";
	mes "服の色^000000を^C00000必ず^000000デフォルト（^ff2222０番^000000）に";
	mes "戻しておいて下さい。";
	mes "服の色を戻さないで行うと";
	mes "そのキャラは重力エラーによる";
	mes "^C00000二度とログインできなくなります^000000。";
	next;
	if(select("知るか。","わかりました。")==1) goto Lfail2;
	mes "[コーディネーター]";
	mes "改めて申しますと、";
	mes "性転換は^C00000アカウント単位^000000で行われます。";
	mes "^0000FF操作中キャラだけが装備を外したり";
	mes "服の色を元に戻しても、^C00000別キャラに";
	mes "回復不可能な問題が起こる^000000";
	mes "可能性があります。";
	next;
	if(select("知るか。","わかりました。")==1) goto Lfail2;
	mes "[コーディネーター]";
	mes "以上の注意事項をすべて理解、";
	mes "実行した上で性転換を行いますか？";
	next;
	if(select("やめます。","性転換します。")==1) {
		mes "[コーディネーター]";
		mes "賢明な判断でございます。";
		goto L_CLOSE;
	}
	mes "[コーディネーター]";
	mes "次のボタンを押せば、";
	mes "性転換の操作によるの";
	mes "強制ログアウトが起こります。";
	mes "もう一度ログインすれば";
	mes "すべての操作が完了します。";
	next;
	if (Class == 19)||(Class == 20)	unequip -1;
	setlook 7,0;
	changesex;
Lexit:
	mes "[コーディネーター]";
	mes "ご利用ありがとうございました。";
	goto L_CLOSE;
Lfail2:
	mes "[コーディネーター]";
	mes "そう･･･、申し訳ありませんが、";
	mes "操作を中止させていただきます。";
	goto L_CLOSE;
MISS:
	mes "[コーディネーター]";
	mes "入力が不正です。";
L_CLOSE:
	close2;
	cutin "wedding_marry01",255;
	end;
}
//-----------------------------------------------
//設置例
prontera.gat,156,156,5		duplicate(coordinator)	コーディネーター#01	71