pvp_n_1-2.gat,97,130,4	script	モンスター召喚屋#A	738,{
	set @Mobs_file$, "db/mob_db.txt";
	set @TrueMob_file$, "db/truemob_db.txt";
	if($@Mob_countA > 0) goto MobAlive;
	mes "[モンスター召喚屋]";
	mes "ん？俺に何かようか？";
	next;
	menu "モンスターを召喚してくれ",-,"同じものを出してくれ",Reload,"ようはない",Exit;

	while(1) {
		mes "[モンスター召喚屋]";
		mes "ふむ・・・。";
		mes "何を召喚するか名前言ってくれ";
		mes "やめるなら、^ff0000半角^000000スペースか";
		mes "^ff0000スペース^000000を入力してくれ";
		mes "あと、^ff0000フィールド^000000にいるのしか";
		mes "出せないからな！！";
		next;
		input @Mob_name$;
		if(@Mob_name$ == " " || @Mob_name$ == "　") goto Exit;
		if(csvfind(@Mobs_file$,2,@Mob_name$) == -1) {
			mes "[モンスター召喚屋]";
			mes "そんなモンスターいねぇよ";
			next;
			continue;
		}
		if(csvfind(@TrueMob_file$,0,@Mob_name$) != -1) break;

		mes "[モンスター召喚屋]";
		mes "出せるのは、";
		mes "^ff0000フィールド^000000のだけだと";
		mes "言っただろ！！";
		next;
	}

	while(1) {
		mes "[モンスター召喚屋]";
		mes "どのくらい出す？";
		mes "出せるのは20体までだ";
		mes "あと、やめるときは0を入力してくれ";
		next;
		input $@Mob_countA;
		if($@Mob_countA == 0) goto Exit;
		if($@Mob_countA > 0 && $@Mob_countA <= 20) break;
		mes "[モンスター召喚屋]";
		mes "そんなに出せるわけないだろバカ野郎！";
		next;
	}
	set @Mob_count,$@Mob_countA;

	mes "[モンスター召喚屋]";
	mes @Mob_name$ + "を" + $@Mob_countA + "体出すが本当にいいか？";
	next;
	menu "はい",-,"いいえ",Exit;
	areamonster "pvp_n_1-2.gat",90,90,110,110,"--ja--",@Mob_name$,$@Mob_countA,"SummonMob#A";
	close;

Reload:
	if(@Mob_count > 0) {
		set $@Mob_countA,@Mob_count;
		areamonster "pvp_n_1-2.gat",90,90,110,110,"--ja--",@Mob_name$,@Mob_count,"SummonMob#A";
		close;
	} else {
		mes "[モンスター召喚屋]";
		mes "まだモンスター出してないだろうが！";
		close;
	}

Exit:
	set $@Mob_countA,0;
	mes "[モンスター召喚屋]";
	mes "またようがあったら";
	mes "ここにきな";
	close;

MobAlive:
	mes "[モンスター召喚屋]";
	mes "なんだ？もう降参するのか？";
	next;
	menu "もう無理",-,"まだいける",Retry;
	mes "[モンスター召喚屋]";
	mes "仕方がないなぁ・・・。";
	killmonsterall "this";
	set $@Mob_countA,0;
	announce strcharinfo(0) + "によりモンスターがリセットされました。",0x04,0x10;
	next;
	mes "[モンスター召喚屋]";
	mes "まったく・・・";
	mes "倒せねぇなら最初から出すなよな";
	mes "こちとら忙しいんだよ！";
	close;
Retry:
	mes "[モンスター召喚屋]";
	mes "じゃぁ、死なない程度に";
	mes "がんばれよ。";
	close;
}

pvp_n_1-2.gat,1,1,4	script	SummonMob#A	-1,{
	set $@Mob_countA,$@Mob_countA-1;
	end;
}