//改造ジョンダ http://test-ro.net78.net/

//ジョンダ職員
//	位置セーブサービス(面倒なので足元セーブ)
//	空間移動サービス
//	倉庫サービス
//	ギルド倉庫サービス
//	銀行サービス
//	オプション貸出

-	script	ジョンダ職員#Zonda	874,{
	//--------設定---------
	set @name$,	"[ジョンダ職員]";		//名前

	set '@Potal_Zeny,1000;	//ポタ金(貧乏免除)

	set '@S_Zeny,100;	//倉庫金

	set '@G_Zeny,1000;	//ギルド倉庫金

	set '@B_Margin,1;	//銀行マージン(%)

	if ('db_first < 1) {
		set 'mapid$,"script/original/db/teleport.txt";

	//--------終了---------
		set 'db_first, 1;
	}
	function message {
		switch (getarg(0)){
			case 1://初めに話したとき
				mes @name$;
				mes "いらっしゃいませ。";
				mes "（有）ジョンダイベントは、常に";
				mes "最高のサービスを提供しております。";
				mes "どのサービスをご利用いたしますか？";
				next;
				break;
			case 11://セーブ
				mes @name$;
				mes "セーブいたしました。";
				mes "ご利用頂きまして、";
				mes "誠にありがとうございます。";
				break;
			case 21://空間移動
				mes @name$;
				mes "目的地を選んでください。";
				break;
			case 22://内容表示
				mes "料金は一律" + getarg(1) + "zです。";
				mes "足りない場合は免除されます。";
				break;
			case 31://貸出共通
				mes @name$;
				mes getarg(1) + "利用料金は " + getarg(2) + " Zenyです。";
				mes "準備はよろしいですか？";
				next;
				break;
			case 32://貸出共通(使用中)
				mes @name$;
				mes "大変申し訳ございませんが、";
				mes "お客様は現在" + getarg(1) + "を";
				mes "ご利用されております。";
				next;
				break;
			case 33://貸出共通(スキル不足)
				mes @name$;
				mes "大変申し訳ございませんが、";
				mes "スキル不足のため、ご利用できません。";
				break;
			case 34://貸出共通(お金不足)
				mes @name$;
				mes "お客様、" + getarg(1) + "利用料金は";
				mes getarg(2) + " Zenyです。";
				mes "大変申し訳ございませんが、";
				mes "所持金をお確かめの上、";
				mes "再度話し掛けてください。";
				break;
			case 35://貸出(無し)
				mes @name$;
				mes "お客様、大変申し訳ございませんが、";
				mes "お客様のご利用できるオプションは";
				mes "今のところ無いようです。";
				break;
			case 41://倉庫(スキル不足)
				mes @name$;
				mes "誠に申し訳ございません、お客様。";
				mes "倉庫は、基本スキルレベル6を";
				mes "習得してから利用可能となります。";
				break;
			case 42://倉庫共通(お金不足)
				mes @name$;
				mes "お客様、倉庫利用料は";
				mes getarg(1) + " Zenyとなっております。";
				mes "大変申し訳ございませんが、";
				mes "所持金をお確かめの上、";
				mes "再度話し掛けてください。";
				break;
			case 43://G倉庫(他人使用)
				mes @name$;
				mes "ギルドメンバーが倉庫を使用中です。";
				mes "しばらく待ってから利用してください。";
				break;
			case 44://G倉庫(ギルド未所属)
				mes @name$;
				mes "ギルドに所属してない方は利用できません。";
				break;
			case 50://銀行
				mes @name$;
				mes "現在の預金額は" + #Bank_Zeny + "Mzです。";
				mes "1Mzからのご利用になります。";
				mes "預金には手数料として、預金額の";
				mes getarg(1) + " %頂きます。";
				mes "引き出す時はマイナスの値で入力してください。";
				mes "キャンセルの時は0を入力してください。";
				next;
				break;
			case 51://銀行(入力ミス？)
				mes @name$;
				mes "値がおかしいです。";
				mes "もう一度ご確認ください。";
				mes "---";
				mes "「 1」で1,000,000zの預金です。";
				mes "「-1」で1,000,000zの引き出しです。";
				next;
				break;
			case 52://預金(所持金不足)
				mes @name$;
				mes "お金が足りませんね。";
				mes "もう一度ご確認ください。";
				next;
				break;
			case 53://手数料
				mes "手数料は" + getarg(1) + "zでした。";
				break;
			case 54://預ける
				mes "預金額は" + getarg(1) + "Mzになりました。";
				break;
			case 98://終了(フォロースルーだっけ？)
				mes @name$;
				mes "（有）ジョンダイベントは、お客様に";
				mes "常に最高のサービスを";
				mes "提供いたしております。";
				mes "ご意見・ご要望などございましたら、";
				mes "いつでもおっしゃってください。";
				next;
			case 99://キャンセル
				mes @name$;
				mes "ありがとうございました。";
				mes "またのご利用をお待ちしております。";
				break;
		}
		return;
	}
	cutin "zonda_01",2;
	message 1;
	switch(select("位置セーブサービス","空間移動サービス","倉庫 -" +'@S_Zeny+ "z","ギルド倉庫 -" +'@G_Zeny+ "z","銀行サービス","オプション貸出","終了")) {
		case 1:
			set '@dummy,getmapxy('@map$, '@mapx, '@mapy, 0);
			savepoint '@map$, '@mapx, '@mapy;
			message 11;
			break;
		case 2:
			message 21;
			if ('@Potal_Zeny > 0) message 22,'@Potal_Zeny;
			next;
			set '@level,1;
			set '@row_num,1;
			while (1) {
				for(set '@line, 1; '@row_num < 999; set '@row_num, '@row_num + 1) {
					set '@check, csvread('mapid$, '@row_num, 0);
					if ( '@check > '@level ) continue;
					if ( '@check < '@level ) break;
					set '@type$['@line], csvread('mapid$, '@row_num, 1);
					if ( '@check == 9 ){
						set '@type$['@line], '@type$['@line] + " (" + getmapusers(csvread('mapid$, '@row_num, 2)) + "人/" + getmapmobs(csvread('mapid$, '@row_num, 2)) + "匹)";
					}
					if (!Last_Portal){
						if ('@type$['@line] == "リベンジ") {
							set '@type$['@line], "";
						}
					}
					set '@row['@line], '@row_num;
					set '@line,'@line + 1;
				}
				if ('@level == 1) set '@type$['@line],"やめる";
				else set '@type$['@line],"戻る";
				cleararray '@type$['@line + 1],"",20;
				if ((select(printarray('@type$)) - 1) == '@line){
					if ('@level == 1){
						cutin "zonda_01",255;
						close2;
						end;
					}
					set '@level, 1;
					set '@row_num, 1;
					continue;
				}
				set @menu, @menu - 1;
				if ('@type$[@menu] == "リベンジ") break;
				set '@row_num, '@row[@menu] + 1;
				set '@check, csvread('mapid$, '@row_num, 0);
				if ('@check <= '@level) {
					set Last_Portal, '@row[@menu];
					break;
				}
				set '@level,'@check;
			}
			set '@map_name$,csvread('mapid$, Last_Portal, 2);	//MAP名
			set '@map_pos_x,csvread('mapid$, Last_Portal, 3);	//X座標
			set '@map_pos_y,csvread('mapid$, Last_Portal, 4);	//Y座標
			if (Zeny > '@Potal_Zeny) set Zeny, Zeny - '@Potal_Zeny;
			warp '@map_name$,'@map_pos_x,'@map_pos_y;	//ワープ
			break;
		case 3:
			if(basicskillcheck() && getskilllv(1) < 6) {
				message 41;
				break;
			}
			if(Zeny < '@S_Zeny) {
				message 42,'@S_Zeny;
				break;
			}
			set Zeny,Zeny-'@S_Zeny;
			openstorage;
			message 99;
			break;
		case 4:
			if(Zeny < '@G_Zeny) {
				message 42,'@G_Zeny;
				break;
			}
			switch(guildopenstorage()){
				case 1:
					message 43;
					break;
				case 2:
					message 44;
					break;
				default:
					set Zeny,Zeny-'@G_Zeny;
					message 99;
			}
			break;
		case 5:
			message 50,'@B_Margin;
			input '@Input_Zeny;
			if ('@Input_Zeny == 0)
				message 99;
			else if('@Input_Zeny > 9999 || '@Input_Zeny < -9999 || #Bank_Zeny + '@Input_Zeny < 0)
				message 51;
			else{
				message 99;
				mes "---";
				if('@Input_Zeny > 0){
					set '@Margin, '@Input_Zeny * '@B_Margin * 10000;
					message 53,'@Margin;
					if ('@Input_Zeny * 1000000 + '@Tmp_Zeny > Zeny){
						message 52;
						break;
					}
				}
				set Zeny, Zeny - '@Input_Zeny * 1000000 - '@Tmp_Zeny;
				set #Bank_Zeny, #Bank_Zeny + '@Input_Zeny;
				message 54,#Bank_Zeny;
			}
			break;
		case 6:
			if(Class == 5 || Class == 10 || Class == 18 || Class == 23) {
				set '@Type$,"カート";
				set '@Cost,800;
				if(checkcart()) {
					message 32,'@Type$;
					break;
				}
				if(getskilllv(39) < 1){
					message 33;
					break;
				}
				message 31,'@Type$,'@Cost;
				if(select("利用する","取り消し")==2) {
					message 99;
					break;
				}
				if(Zeny < '@Cost) {
					message 34,'@Type$,'@Cost;
					break;
				}
				set Zeny,Zeny-'@Cost;
				setcart;
				break;
			}
			else if(Class == 11) {
				set '@Type$,"ファルコン";
				set '@Cost,2500;
				if(checkfalcon()) {
					message 32,'@Type$;
					break;
				}
				if(getskilllv(127) < 1){
					message 33;
					break;
				}
				message 31,'@Type$,'@Cost;
				if(select("利用する","取り消し")==2) {
					message 99;
					break;
				}
				if(Zeny < '@Cost) {
					message 34,'@Type$,'@Cost;
					break;
				}
				set Zeny,Zeny-'@Cost;
				setfalcon;
				break;
			}
			else if(Class == 7 || Class == 14) {
				set '@Type$,"ペコペコ";
				set '@Cost,3500;
				if(checkriding()) {
					message 32,'@Type$;
					break;
				}
				if(getskilllv(63) < 1){
					message 33;
					break;
				}
				message 31,'@Type$,'@Cost;
				if(select("利用する","取り消し")==2) {
					message 99;
					break;
				}
				if(Zeny < '@Cost) {
					message 34,'@Type$,'@Cost;
					break;
				}
				set Zeny,Zeny-'@Cost;
				setriding;
				break;
			}
			else {
				message 35;
				break;
			}
		case 7:
			if(getgmlevel() > 10) csvreload 'mapid$;
			message 98;
			break;
	}
	cutin "zonda_01",255;
	close2;
	end;
}
lighthalzen.gat,94,248,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874	// リヒタルゼン
hugel.gat,97,168,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874	// フィゲル
rachel.gat,109,138,5	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874	// ラヘル
veins.gat,208,128,5	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874	// ベインス
izlude.gat,134,88,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
geffen.gat,120,62,0	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
geffen.gat,203,123,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
morocc.gat,156,97,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
morocc.gat,160,258,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
moc_ruins.gat,59,157,6	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
alberta.gat,28,229,0	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
alberta.gat,113,60,6	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
alb2trea.gat,59,69,6	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
payon.gat,175,226,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
payon.gat,181,104,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
pay_arche.gat,55,123,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
aldebaran.gat,143,119,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
cmd_in02.gat,146,180,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
cmd_fild07.gat,136,134,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
comodo.gat,195,150,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
gef_fild10.gat,73,340,5	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
mjolnir_02.gat,82,362,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
yuno.gat,152,187,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
yuno.gat,327,109,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
yuno.gat,277,221,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
amatsu.gat,102,149,5	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
gonryun.gat,159,122,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
umbala.gat,87,160,5	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
niflheim.gat,202,180,3	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
louyang.gat,210,104,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
ayothaya.gat,212,169,6	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
einbroch.gat,242,205,5	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
einbroch.gat,59,203,5	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
einbech.gat,181,132,5	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
lighthalzen.gat,191,320,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
lighthalzen.gat,164,100,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
lhz_in02.gat,237,284,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
moscovia.gat,223,191,3	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
prontera.gat,248,42,0	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
izlu2dun.gat,106,58,4	duplicate(ジョンダ職員#Zonda)	ジョンダ職員	874
//---