//=====================================================================
// 大絡繰屋敷 - 第1ステージ	TestVer		by Blaze
//=====================================================================
pvp_n_1-3_e.gat	mapflag	nomemo	dummy
pvp_n_1-3_e.gat	mapflag	noteleport	dummy
pvp_n_1-3_e.gat	mapflag	nosave	SavePoint
pvp_n_1-3_e.gat	mapflag	nobranch	dummy
pvp_n_1-3_e.gat	mapflag	nopenalty	dummy
pvp_n_1-3_e.gat	mapflag	noskill	dummy
//=====================================================================
amatsu.gat,228,165,4	script	アトラクション係員	763,{
	mes "[係員]";
	mes "こちらではテスト中のマップへ";
	mes "ご案内しています。";
	mes "多人数での参加ができますので";
	mes "ぜひパーティーでお越しください。";
	next;
	if(select("テストマップへ転送","やめる")==2)
		close;
	mes "[係員]";
	mes "パーティーでご参加の方々は";
	mes "遠くにいると確認できませんので";
	mes "私の周りに近寄ってください。";
	mes "よろしいですか？";
	next;
	if(select("はい","いいえ")==2)
		close;
	close2;
	areawarp "amatsu.gat",223,160,233,170,"pvp_n_1-3_e.gat",106,98;
	end;
}

pvp_n_1-3_e.gat,100,95,4	script	アトラクション係員	757,{
	mes "[係員 綾香]";
	mes "東西南北に、";
	mes "大量のおばけが出現しています！";
	mes "その中に紛れている";
	mes "当たりおばけを倒すと、";
	mes "全員第2ステージへと移動できます。";
	next;
	mes "[係員 綾香]";
	mes "ただし、ハズレおばけも紛れて";
	mes "いますので、注意してください。";
	mes "さぁ、第1ステージ突破を目指し、";
	mes "頑張ってください！";
	next;
	mes "[係員 綾香]";
	mes "現在テスト中です。";
	mes "テスト実行してみますか？";
	next;
	if(select("テストする","やめる")==1) {
		killmonster "pvp_n_1-3_e.gat","All";
		announce "テストを開始します。",9;
		mes "[係員 綾香]";
		mes "テストを開始します。";
		donpcevent "Karakuri1::OnStart";
		close;
	}
	mes "[係員 綾香]";
	mes "テストを終了し、";
	mes "街へ戻りますか？";
	next;
	if(select("戻る","やめる")==2)
		close;
	close2;
	announce "テストを終了します。",9;
	sleep 2000;
	areawarp "pvp_n_1-3_e.gat",0,0,180,180,"amatsu.gat",200,110;
	end;
}

pvp_n_1-3_e.gat,0,0,0	script	Karakuri1	-1,{
OnStart:
	set '@flag,rand(4);		//当たり方角セット
	for(set '@i,0; '@i<4; set '@i,'@i+1) {
		switch('@i) {
		case 0:
			set '@x,56;	//開始X地点
			set '@y,95;	//開始Y地点
			set '@xc,2;	//X増幅
			set '@yc,3;	//Y増幅
			break;
		case 1:
			set '@x,134;
			set '@y,95;
			break;
		case 2:
			set '@x,94;
			set '@y,56;
			set '@xc,3;
			set '@yc,2;
			break;
		case 3:
			set '@x,94;
			set '@y,134;
			break;
		}
		for(set '@j,0; '@j<5; set '@j,'@j+1) {
			for(set '@k,0; '@k<5; set '@k,'@k+1) {
				monster "pvp_n_1-3_e.gat",'@x,'@y,"おばけ",1185,1;
				set '@x,'@x+'@xc;
			}
			set '@x,'@x-('@xc*5);
			set '@y,'@y+'@yc;
		}
		set '@y,'@y-('@yc*5);
		set '@xr,'@x+('@xc*rand(5));
		set '@yr,'@y+('@yc*rand(5));
		areakillmonster "pvp_n_1-3_e.gat",'@xr,'@yr,'@xr,'@yr;		//重複したおばけを削除、本鯖仕様はコメントアウト
		monster "pvp_n_1-3_e.gat",'@xr,'@yr,"おばけ",1185,1,"Karakuri1::OnFailed";		//はずれは各方角1匹ずつ
		if('@flag == '@i) {
			set '@xr,'@x+('@xc*rand(5));
			set '@yr,'@y+('@yc*rand(5));
			areakillmonster "pvp_n_1-3_e.gat",'@xr,'@yr,'@xr,'@yr;	//重複したおばけを削除、本鯖仕様はコメントアウト
			monster "pvp_n_1-3_e.gat",'@xr,'@yr,"おばけ",1185,1,"Karakuri1::OnSuccess";	//当たりは全体で1匹
		}
	}
	initnpctimer;
	end;
OnFailed:
	announce strcharinfo(0)+"様が、ハズレおばけを倒してしまった！　マップ中央からおばけが襲ってきます！",9,0x7B6BEF;
	areamonster "pvp_n_1-3_e.gat",83,83,116,116,"おばけ",1179,getmapusers("pvp_n_1-3_e.gat")*(BaseLevel/20+1);
	end;
OnSuccess:
	killmonster "pvp_n_1-3_e.gat","All";
	announce strcharinfo(0)+"様が、当たりおばけを撃破！　5秒後に第2ステージへ移動いたします。",9,0x7B6BEF;
	end;
OnTimer5000:
	stopnpctimer;
	announce "第1ステージ",9;
	sleep 5000;
	announce "東西南北に、大量のおばけが出現しています！",9;
	sleep 2000;
	announce "その中に紛れている当たりおばけを倒すと、全員第2ステージへと移動できます。",9;
	sleep 2000;
	announce "ただし、ハズレおばけも紛れていますので、注意してください。",9;
	sleep 2000;
	announce "さぁ、第1ステージ突破を目指し、頑張ってください！",9;
	end;
}